1 files changed, 42 insertions, 0 deletions
diff --git a/dev-python/websocket-client/websocket-client-0.48.0.ebuild b/dev-python/websocket-client/websocket-client-0.48.0.ebuild
new file mode 100644
index 000000000000..a82bb5438c35
--- /dev/null
+++ b/dev-python/websocket-client/websocket-client-0.48.0.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy{,3} python{2_7,3_{4,5,6}} )
+
+inherit distutils-r1
+
+MY_PN=${PN//-/_}
+
+DESCRIPTION="WebSocket client for python with hybi13 support"
+HOMEPAGE="https://github.com/websocket-client/websocket-client"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${MY_PN}-${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x64-macos ~x86"
+IUSE="examples test"
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'dev-python/backports-ssl-match-hostname[${PYTHON_USEDEP}]' pypy python2_7 )
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( ${RDEPEND} )
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		dodoc -r examples
+	fi
+	distutils-r1_python_install_all
+}