1 files changed, 44 insertions, 0 deletions
diff --git a/dev-python/watchdog/watchdog-2.1.7.ebuild b/dev-python/watchdog/watchdog-2.1.7.ebuild
new file mode 100644
index 000000000000..c7201e2d04e8
--- /dev/null
+++ b/dev-python/watchdog/watchdog-2.1.7.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Python API and shell utilities to monitor file system events"
+HOMEPAGE="https://github.com/gorakhargosh/watchdog"
+SRC_URI="
+	https://github.com/gorakhargosh/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/pytest-timeout-0.3[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e '/--cov/d' setup.cfg || die
+	default
+}
+
+python_test() {
+	epytest -p no:django
+}
+
+pkg_postinst() {
+	optfeature "Bash completion" dev-python/argcomplete
+}