1 files changed, 60 insertions, 0 deletions
diff --git a/dev-python/tree-sitter/tree-sitter-0.22.2-r1.ebuild b/dev-python/tree-sitter/tree-sitter-0.22.2-r1.ebuild
new file mode 100644
index 000000000000..5560b9fb2c6f
--- /dev/null
+++ b/dev-python/tree-sitter/tree-sitter-0.22.2-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python bindings to the Tree-sitter parsing library"
+HOMEPAGE="
+	https://github.com/tree-sitter/py-tree-sitter/
+	https://pypi.org/project/tree-sitter/
+"
+SRC_URI="
+	https://github.com/tree-sitter/py-tree-sitter/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S=${WORKDIR}/py-${P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~s390"
+
+# setuptools is needed for distutils import
+DEPEND=">=dev-libs/tree-sitter-0.22.1:="
+RDEPEND="${DEPEND}
+	$(python_gen_cond_dep '
+		dev-python/setuptools[${PYTHON_USEDEP}]
+	' 3.12)
+"
+BDEPEND="
+	test? (
+		>=dev-libs/tree-sitter-html-0.20.3[python,${PYTHON_USEDEP}]
+		>=dev-libs/tree-sitter-javascript-0.21.0[python,${PYTHON_USEDEP}]
+		>=dev-libs/tree-sitter-json-0.20.3[python,${PYTHON_USEDEP}]
+		>=dev-libs/tree-sitter-python-0.21.0[python,${PYTHON_USEDEP}]
+		>=dev-libs/tree-sitter-rust-0.21.2[python,${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.22.2-unbundle.patch
+	# Fix 32-bit build, upstream, drop on next bump
+	"${FILESDIR}"/${P}-fix-32-bit.patch
+)
+
+src_unpack() {
+	default
+	rmdir "${S}/tree_sitter/core" || die
+}
+
+src_test() {
+	rm -r tree_sitter || die
+	distutils-r1_src_test
+}