1 files changed, 52 insertions, 0 deletions
diff --git a/dev-python/tqdm/tqdm-4.33.0.ebuild b/dev-python/tqdm/tqdm-4.33.0.ebuild
new file mode 100644
index 000000000000..9a0b9b8ea059
--- /dev/null
+++ b/dev-python/tqdm/tqdm-4.33.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy{,3} python{2_7,3_{5,6,7}} )
+
+inherit distutils-r1
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/tqdm/tqdm"
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Add a progress meter to your loops in a second"
+HOMEPAGE="https://github.com/tqdm/tqdm"
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="examples test"
+
+# Uses pkg_resources
+RDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( dev-python/nose[${PYTHON_USEDEP}] )
+"
+
+python_test() {
+	# tests_main.py requires the package to be installed
+	distutils_install_for_testing
+	# Skip unpredictable performance tests
+	nosetests tqdm -v -I 'tests_perf.py' \
+		|| die "tests failed with ${EPYTHON}"
+}
+
+python_install() {
+	doman "${BUILD_DIR}"/lib/tqdm/tqdm.1
+	rm "${BUILD_DIR}"/lib/tqdm/tqdm.1 || die
+	distutils-r1_python_install --skip-build
+}
+
+python_install_all() {
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+	distutils-r1_python_install_all
+}