1 files changed, 45 insertions, 0 deletions
diff --git a/dev-python/subprocess-tee/subprocess-tee-0.4.1.ebuild b/dev-python/subprocess-tee/subprocess-tee-0.4.1.ebuild
new file mode 100644
index 000000000000..100597cf333b
--- /dev/null
+++ b/dev-python/subprocess-tee/subprocess-tee-0.4.1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1
+
+DESCRIPTION="subprocess.run replacement with tee(1)-like output"
+HOMEPAGE="
+	https://github.com/pycontribs/subprocess-tee/
+	https://pypi.org/project/subprocess-tee/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv"
+IUSE="test-full"
+REQUIRED_USE="test-full? ( test )"
+
+# ansible-molecule is invoked as an executable so no need for PYTHON_USEDEP
+BDEPEND="
+	>=dev-python/setuptools_scm-7.0.0[${PYTHON_USEDEP}]
+	test? (
+		dev-python/enrich[${PYTHON_USEDEP}]
+		test-full? ( app-admin/ansible-molecule )
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=()
+
+	if ! use test-full; then
+		EPYTEST_DESELECT+=(
+			test/test_func.py::test_molecule
+		)
+	fi
+
+	epytest
+}