1 files changed, 55 insertions, 0 deletions
diff --git a/dev-python/rich/rich-13.6.0.ebuild b/dev-python/rich/rich-13.6.0.ebuild
new file mode 100644
index 000000000000..cdffd9766be3
--- /dev/null
+++ b/dev-python/rich/rich-13.6.0.ebuild
@@ -0,0 +1,55 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Python library for rendering rich text, tables, etc. to the terminal"
+HOMEPAGE="
+	https://github.com/Textualize/rich/
+	https://pypi.org/project/rich/
+"
+SRC_URI="
+	https://github.com/Textualize/rich/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/colorama[${PYTHON_USEDEP}]
+	>=dev-python/markdown-it-py-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.13.0[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO
+		tests/test_console.py::test_size_can_fall_back_to_std_descriptors
+	)
+	# version-specific output -- the usual deal
+	case ${EPYTHON} in
+		pypy3)
+			EPYTEST_DESELECT+=(
+				# pypy3.10, to be more precise
+				tests/test_inspect.py::test_inspect_integer_with_methods_python310only
+			)
+			;;
+	esac
+
+	local -x COLUMNS=80
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}
+
+pkg_postinst() {
+	optfeature "integration with HTML widgets for Jupyter" dev-python/ipywidgets
+}