1 files changed, 61 insertions, 0 deletions
diff --git a/dev-python/pyzmq/pyzmq-19.0.0.ebuild b/dev-python/pyzmq/pyzmq-19.0.0.ebuild
new file mode 100644
index 000000000000..be7f07be845a
--- /dev/null
+++ b/dev-python/pyzmq/pyzmq-19.0.0.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit flag-o-matic distutils-r1 toolchain-funcs
+
+DESCRIPTION="Lightweight and super-fast messaging library built on top of the ZeroMQ library"
+HOMEPAGE="https://www.zeromq.org/bindings:python https://pypi.org/project/pyzmq/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~mips ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="doc +draft test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=net-libs/zeromq-4.2.2-r2:=[drafts]
+	dev-python/py[${PYTHON_USEDEP}]
+	dev-python/cffi:=[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	dev-python/cython[${PYTHON_USEDEP}]
+	test? (
+		>=www-servers/tornado-5.0.2[${PYTHON_USEDEP}]
+	)
+	doc? (
+		>=dev-python/sphinx-1.3[${PYTHON_USEDEP}]
+		dev-python/numpydoc[${PYTHON_USEDEP}]
+	)"
+
+PATCHES=(
+	"${FILESDIR}/pyzmq-19.0.0-tests.patch"
+)
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+	"dev-python/numpydoc"
+
+python_prepare_all() {
+	# Prevent un-needed download during build
+	sed -e "/'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
+	# some tests fail with cffi backend
+	rm zmq/tests/asyncio/test_asyncio.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_configure_all() {
+	tc-export CC
+	append-cppflags -DZMQ_BUILD_DRAFT_API=$(usex draft '1' '0')
+}
+
+python_compile() {
+	esetup.py cython --force
+	distutils-r1_python_compile
+}