1 files changed, 47 insertions, 0 deletions
diff --git a/dev-python/pyyaml/pyyaml-5.3.1.ebuild b/dev-python/pyyaml/pyyaml-5.3.1.ebuild
new file mode 100644
index 000000000000..88b24f47bd92
--- /dev/null
+++ b/dev-python/pyyaml/pyyaml-5.3.1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=no
+PYTHON_COMPAT=( python2_7 python3_{6,7,8} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="YAML parser and emitter for Python"
+HOMEPAGE="https://pyyaml.org/wiki/PyYAML
+	https://pypi.org/project/PyYAML/
+	https://github.com/yaml/pyyaml"
+SRC_URI="https://github.com/yaml/pyyaml/archive/${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~m68k ~mips ppc ppc64 ~riscv s390 sparc x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
+IUSE="examples +libyaml"
+
+RDEPEND="libyaml? ( dev-libs/libyaml:= )"
+DEPEND="${RDEPEND}
+	libyaml? (
+		$(python_gen_cond_dep '
+			dev-python/cython[${PYTHON_USEDEP}]
+		' 'python*')
+	)"
+
+PATCHES=(
+	# bug #659348
+	"${FILESDIR}/pyyaml-5.1-cve-2017-18342.patch"
+)
+
+distutils_enable_tests setup.py
+
+python_configure_all() {
+	mydistutilsargs=( $(use_with libyaml) )
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}
+	fi
+}