1 files changed, 43 insertions, 0 deletions
diff --git a/dev-python/pytest-xdist/pytest-xdist-3.6.0.ebuild b/dev-python/pytest-xdist/pytest-xdist-3.6.0.ebuild
new file mode 100644
index 000000000000..602cb721af56
--- /dev/null
+++ b/dev-python/pytest-xdist/pytest-xdist-3.6.0.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Distributed testing and loop-on-failing modes"
+HOMEPAGE="
+	https://pypi.org/project/pytest-xdist/
+	https://github.com/pytest-dev/pytest-xdist/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+	>=dev-python/execnet-2.1[${PYTHON_USEDEP}]
+	dev-python/psutil[${PYTHON_USEDEP}]
+	>=dev-python/pytest-7.0.0[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/filelock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	# disable autoloading plugins in nested pytest calls
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	# since we disabled autoloading, force loading necessary plugins
+	local -x PYTEST_PLUGINS=xdist.plugin,xdist.looponfail
+
+	epytest -o tmp_path_retention_count=1
+}