1 files changed, 57 insertions, 0 deletions
diff --git a/dev-python/pytest-cov/pytest-cov-2.6.1.ebuild b/dev-python/pytest-cov/pytest-cov-2.6.1.ebuild
new file mode 100644
index 000000000000..7af2f09e3383
--- /dev/null
+++ b/dev-python/pytest-cov/pytest-cov-2.6.1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{5,6,7} pypy pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="py.test plugin for coverage reporting"
+HOMEPAGE="https://github.com/pytest-dev/pytest-cov https://pypi.org/project/pytest-cov/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-fbsd"
+IUSE="doc test"
+
+RDEPEND="
+	>=dev-python/py-1.4.22[${PYTHON_USEDEP}]
+	>=dev-python/pytest-3.6[${PYTHON_USEDEP}]
+	>=dev-python/coverage-4.4[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/sphinx-py3doc-enhanced-theme[${PYTHON_USEDEP}]
+	)
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/virtualenv[${PYTHON_USEDEP}]
+		dev-python/fields[${PYTHON_USEDEP}]
+		dev-python/process-tests[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	# Bug 597708
+	"${FILESDIR}/${PN}-2.6.1-disable-broken-tests.patch"
+)
+
+python_compile_all() {
+	use doc && sphinx-build -b html docs _build/html
+}
+
+python_test() {
+	distutils_install_for_testing
+	PYTHONPATH="${S}/tests:${BUILD_DIR}/lib:${PYTHONPATH}" \
+		PYTEST_PLUGINS=${PN/-/_} \
+		pytest -vv || die "Tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( _build/html/. )
+	distutils-r1_python_install_all
+}