1 files changed, 37 insertions, 0 deletions
diff --git a/dev-python/pyserial/pyserial-3.5-r2.ebuild b/dev-python/pyserial/pyserial-3.5-r2.ebuild
new file mode 100644
index 000000000000..a8e14ce8e27f
--- /dev/null
+++ b/dev-python/pyserial/pyserial-3.5-r2.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python Serial Port extension"
+HOMEPAGE="
+	https://github.com/pyserial/pyserial/
+	https://pypi.org/project/pyserial/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~arm64-macos ~x64-macos"
+IUSE="examples"
+
+DOCS=( CHANGES.rst README.rst )
+
+distutils_enable_sphinx documentation --no-autodoc
+
+python_test() {
+	"${EPYTHON}" test/run_all_tests.py loop:// -v ||
+		die "Testing failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}