1 files changed, 46 insertions, 0 deletions
diff --git a/dev-python/pycairo/pycairo-1.21.0-r1.ebuild b/dev-python/pycairo/pycairo-1.21.0-r1.ebuild
new file mode 100644
index 000000000000..86fb89824d83
--- /dev/null
+++ b/dev-python/pycairo/pycairo-1.21.0-r1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Python bindings for the cairo library"
+HOMEPAGE="https://www.cairographics.org/pycairo/ https://github.com/pygobject/pycairo"
+SRC_URI="https://github.com/pygobject/${PN}/releases/download/v${PV}/${P}.tar.gz"
+
+LICENSE="|| ( LGPL-2.1 MPL-1.1 )"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+IUSE="examples"
+
+BDEPEND="
+	test? (
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="
+	>=x11-libs/cairo-1.15.10[svg(+)]
+"
+DEPEND="${RDEPEND}"
+
+distutils_enable_sphinx docs \
+	dev-python/sphinx_rtd_theme
+distutils_enable_tests setup.py
+
+python_install() {
+	distutils-r1_python_install \
+		install_pkgconfig --pkgconfigdir="${EPREFIX}/usr/$(get_libdir)/pkgconfig"
+}
+
+python_install_all() {
+	if use examples; then
+		dodoc -r examples
+	fi
+
+	distutils-r1_python_install_all
+}