1 files changed, 43 insertions, 0 deletions
diff --git a/dev-python/pyasn1/pyasn1-0.3.7.ebuild b/dev-python/pyasn1/pyasn1-0.3.7.ebuild
new file mode 100644
index 000000000000..386b3f4ad63b
--- /dev/null
+++ b/dev-python/pyasn1/pyasn1-0.3.7.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} pypy pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="ASN.1 library for Python"
+HOMEPAGE="http://pyasn1.sourceforge.net/ https://pypi.python.org/pypi/pyasn1"
+SRC_URI="https://github.com/etingof/pyasn1/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+# The required doc/source/conf.py file is missing from the pypi:
+# https://github.com/etingof/pyasn1/issues/35
+#SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x64-cygwin ~x86-fbsd ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
+IUSE="doc"
+
+RDEPEND=""
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+
+python_test() {
+	esetup.py test || die "Tests fail with ${EPYTHON}"
+}
+
+src_compile() {
+	if use doc; then
+		python_setup
+		esetup.py build_sphinx
+	fi
+	distutils-r1_src_compile
+}
+
+src_install() {
+	local HTML_DOCS
+	use doc && HTML_DOCS=( build/sphinx/html/. )
+
+	distutils-r1_src_install
+}