1 files changed, 0 insertions, 64 deletions
diff --git a/dev-python/oslo-utils/oslo-utils-4.13.0-r1.ebuild b/dev-python/oslo-utils/oslo-utils-4.13.0-r1.ebuild
deleted file mode 100644
index fbf7c0e01d64..000000000000
--- a/dev-python/oslo-utils/oslo-utils-4.13.0-r1.ebuild
+++ /dev/null
@@ -1,64 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{8..10} )
-
-inherit distutils-r1
-
-MY_P=${P/-/.}
-DESCRIPTION="Oslo Utility library"
-HOMEPAGE="https://launchpad.net/oslo"
-SRC_URI="mirror://pypi/${PN::1}/${PN/-/.}/${MY_P}.tar.gz"
-S="${WORKDIR}/${MY_P}"
-
-LICENSE="Apache-2.0"
-SLOT="0"
-KEYWORDS="amd64 ~arm arm64 ~riscv x86"
-
-RDEPEND="
-	>=dev-python/iso8601-0.1.11[${PYTHON_USEDEP}]
-	>=dev-python/oslo-i18n-3.15.3[${PYTHON_USEDEP}]
-	>=dev-python/pytz-2013.6[${PYTHON_USEDEP}]
-	>=dev-python/netaddr-0.7.18[${PYTHON_USEDEP}]
-	>=dev-python/netifaces-0.10.4[${PYTHON_USEDEP}]
-	>=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]
-	>=dev-python/pyparsing-2.1.0[${PYTHON_USEDEP}]
-	>=dev-python/packaging-20.4[${PYTHON_USEDEP}]
-	dev-python/pyyaml[${PYTHON_USEDEP}]
-"
-BDEPEND="
-	>=dev-python/pbr-2.2.0[${PYTHON_USEDEP}]
-	test? (
-		$(python_gen_cond_dep '
-			>=dev-python/eventlet-0.23.0[${PYTHON_USEDEP}]
-		' python3_{8..9})
-		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
-		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
-		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
-		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
-		>=dev-python/ddt-1.0.1[${PYTHON_USEDEP}]
-	)
-"
-
-distutils_enable_tests unittest
-
-src_prepare() {
-	# spurious rdep
-	sed -i -e '/pbr/d' requirements.txt || die
-	distutils-r1_src_prepare
-}
-
-python_compile() {
-	distutils-r1_python_compile
-	if ! has "${EPYTHON}" python3.{8..9}; then
-		find "${BUILD_DIR}"/install -name '*eventletutils*.py' -delete || die
-	fi
-}
-
-python_test() {
-	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
-	eunittest
-}