1 files changed, 61 insertions, 0 deletions
diff --git a/dev-python/myst_parser/myst_parser-0.18.1.ebuild b/dev-python/myst_parser/myst_parser-0.18.1.ebuild
new file mode 100644
index 000000000000..a659d750566e
--- /dev/null
+++ b/dev-python/myst_parser/myst_parser-0.18.1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{8..11} pypy3 )
+
+inherit distutils-r1
+
+MY_P=MyST-Parser-${PV}
+DESCRIPTION="Extended commonmark compliant parser, with bridges to sphinx"
+HOMEPAGE="
+	https://github.com/executablebooks/MyST-Parser/
+	https://pypi.org/project/myst-parser/
+"
+SRC_URI="
+	https://github.com/executablebooks/MyST-Parser/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	<dev-python/docutils-0.20[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/markdown-it-py[${PYTHON_USEDEP}]
+	>=dev-python/mdit-py-plugins-0.3.1[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	<dev-python/sphinx-5.2[${PYTHON_USEDEP}]
+	>=dev-python/sphinx-4[${PYTHON_USEDEP}]
+	dev-python/typing-extensions[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+		dev-python/pytest-regressions[${PYTHON_USEDEP}]
+		dev-python/pytest-param-files[${PYTHON_USEDEP}]
+		dev-python/sphinx-pytest[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Unimportant tests needing a new dep linkify
+		tests/test_renderers/test_myst_config.py::test_cmdline
+		tests/test_sphinx/test_sphinx_builds.py::test_extended_syntaxes
+	)
+
+	[[ ${EPYTHON} == pypy3 ]] && EPYTEST_DESELECT+=(
+		# bad test relying on exact exception messages
+		"tests/test_renderers/test_include_directive.py::test_errors[9-Non-existent path:]"
+	)
+
+	epytest
+}