1 files changed, 40 insertions, 0 deletions
diff --git a/dev-python/lazy-object-proxy/lazy-object-proxy-1.3.1.ebuild b/dev-python/lazy-object-proxy/lazy-object-proxy-1.3.1.ebuild
new file mode 100644
index 000000000000..b96994cca333
--- /dev/null
+++ b/dev-python/lazy-object-proxy/lazy-object-proxy-1.3.1.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} pypy )
+
+inherit distutils-r1
+
+DESCRIPTION="A fast and thorough lazy object proxy"
+HOMEPAGE="
+	https://github.com/ionelmc/python-lazy-object-proxy
+	https://pypi.python.org/pypi/lazy-object-proxy
+	https://python-lazy-object-proxy.readthedocs.org/"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="test"
+
+RDEPEND=""
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)"
+
+python_prepare_all() {
+	# No need to benchmark
+	sed \
+		-e '/benchmark/s:test_:_&:g' \
+		-e '/pytest.mark.benchmark/d' \
+		-i tests/test_lazy_object_proxy.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	py.test -v -v --ignore=src || die "Fails for ${EPYTHON}"
+}