1 files changed, 41 insertions, 0 deletions
diff --git a/dev-python/jaraco-context/jaraco-context-3.0.0-r1.ebuild b/dev-python/jaraco-context/jaraco-context-3.0.0-r1.ebuild
new file mode 100644
index 000000000000..9b28336a584e
--- /dev/null
+++ b/dev-python/jaraco-context/jaraco-context-3.0.0-r1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..9} pypy3 )
+
+inherit distutils-r1
+
+MY_PN="${PN/-/.}"
+DESCRIPTION="Context managers by jaraco"
+HOMEPAGE="https://github.com/jaraco/jaraco.context"
+SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="amd64 arm arm64 ~ia64 ppc ~ppc64 x86"
+
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+PATCHES=(
+	"${FILESDIR}"/${P}-useless-deps.patch
+)
+
+python_prepare_all() {
+	# used only for apt support that's irrelevant to Gentoo
+	sed -i -e '/jaraco\.apt/d' -e '/yg\.lockfile/d' setup.cfg || die
+	# pytest plugins
+	sed -i -e 's:--flake8 --black --cov::' pytest.ini || die
+	distutils-r1_python_prepare_all
+}
+
+python_install() {
+	rm "${BUILD_DIR}"/lib/jaraco/__init__.py || die
+	distutils-r1_python_install
+}