1 files changed, 47 insertions, 0 deletions
diff --git a/dev-python/importlib_resources/importlib_resources-1.0.2-r1.ebuild b/dev-python/importlib_resources/importlib_resources-1.0.2-r1.ebuild
new file mode 100644
index 000000000000..5ebc09e8110e
--- /dev/null
+++ b/dev-python/importlib_resources/importlib_resources-1.0.2-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+# This is a backport of Python 3.7's importlib.resources
+PYTHON_COMPAT=( pypy{,3} python{2_7,3_{5,6}} )
+
+inherit distutils-r1
+
+DESCRIPTION="Read resources from Python packages"
+HOMEPAGE="https://importlib-resources.readthedocs.io/en/latest/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+LICENSE="Apache-2.0"
+
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	$(python_gen_cond_dep 'dev-python/pathlib2[${PYTHON_USEDEP}]' -2)
+	virtual/python-typing[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( ${RDEPEND} )
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+# https://gitlab.com/python-devs/importlib_resources/issues/71
+PATCHES=( "${FILESDIR}/${P}-skip-wheel.patch" )
+
+python_prepare_all() {
+	sed -i "/'sphinx.ext.intersphinx'/d" ${PN}/docs/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build ${PN}/docs docs/_build/html || die
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	"${EPYTHON}" -m unittest discover -v || die "tests failed with ${EPYTHON}"
+}