1 files changed, 46 insertions, 0 deletions
diff --git a/dev-python/fs/fs-2.4.13.ebuild b/dev-python/fs/fs-2.4.13.ebuild
new file mode 100644
index 000000000000..99833ddeba7d
--- /dev/null
+++ b/dev-python/fs/fs-2.4.13.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1 optfeature
+
+MY_PN="pyfilesystem2"
+DESCRIPTION="Filesystem abstraction layer"
+HOMEPAGE="
+	https://pypi.org/project/fs/
+	https://docs.pyfilesystem.org
+	https://www.willmcgugan.com/tag/fs/
+"
+# Tests from the PyPI tarball are broken
+# https://github.com/PyFilesystem/pyfilesystem2/issues/364
+SRC_URI="https://github.com/PyFilesystem/pyfilesystem2/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/appdirs-1.4.3[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	>=dev-python/six-1.10[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pyftpdlib[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source dev-python/sphinx_rtd_theme
+distutils_enable_tests pytest
+
+pkg_postinst() {
+	optfeature "S3 support" dev-python/boto
+	optfeature "SFTP support" dev-python/paramiko
+	optfeature "Browser support" dev-python/wxpython
+}