1 files changed, 63 insertions, 0 deletions
diff --git a/dev-python/flask/flask-2.2.3.ebuild b/dev-python/flask/flask-2.2.3.ebuild
new file mode 100644
index 000000000000..486b6e0ce985
--- /dev/null
+++ b/dev-python/flask/flask-2.2.3.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="A microframework based on Werkzeug, Jinja2 and good intentions"
+HOMEPAGE="
+	https://palletsprojects.com/p/flask/
+	https://github.com/pallets/flask/
+	https://pypi.org/project/Flask/
+"
+MY_PN="Flask"
+MY_P="${MY_PN}-${PV}"
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/mitsuhiko/flask.git"
+	inherit git-r3
+else
+	SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+	S="${WORKDIR}/${MY_P}"
+fi
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="examples"
+
+RDEPEND="
+	>=dev-python/click-8.0[${PYTHON_USEDEP}]
+	dev-python/blinker[${PYTHON_USEDEP}]
+	>=dev-python/itsdangerous-2.0[${PYTHON_USEDEP}]
+	>=dev-python/jinja-3.0[${PYTHON_USEDEP}]
+	>=dev-python/werkzeug-2.2[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/importlib_metadata-3.6.0[${PYTHON_USEDEP}]
+	' 3.8 3.9)
+"
+BDEPEND="
+	test? (
+		>=dev-python/asgiref-3.2[${PYTHON_USEDEP}]
+		!!dev-python/shiboken2
+	)
+"
+
+distutils_enable_sphinx docs \
+	dev-python/pallets-sphinx-themes \
+	dev-python/sphinx-issues \
+	dev-python/sphinx-tabs \
+	dev-python/sphinxcontrib-log_cabinet
+distutils_enable_tests pytest
+
+python_test() {
+	epytest -p no:httpbin
+}
+
+python_install_all() {
+	use examples && dodoc -r examples
+	distutils-r1_python_install_all
+}