1 files changed, 45 insertions, 0 deletions
diff --git a/dev-python/clint/clint-0.5.1-r2.ebuild b/dev-python/clint/clint-0.5.1-r2.ebuild
new file mode 100644
index 000000000000..f62be93bf388
--- /dev/null
+++ b/dev-python/clint/clint-0.5.1-r2.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python Command-line Application Tools"
+HOMEPAGE="https://github.com/kennethreitz/clint"
+SRC_URI="https://github.com/kennethreitz/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="amd64 ~arm64 ~x86"
+IUSE="doc examples test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )
+"
+
+# https://github.com/kennethreitz-archive/clint/pull/180
+PATCHES=( "${FILESDIR}/${P}-disable-args-dependency.patch" )
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	py.test || die "Tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	if use examples; then
+		insinto /usr/share/doc/${PF}
+		doins -r examples
+	fi
+
+	distutils-r1_python_install_all
+}