1 files changed, 38 insertions, 0 deletions
diff --git a/dev-python/accessible-pygments/accessible-pygments-0.0.3.ebuild b/dev-python/accessible-pygments/accessible-pygments-0.0.3.ebuild
new file mode 100644
index 000000000000..012b96db64ba
--- /dev/null
+++ b/dev-python/accessible-pygments/accessible-pygments-0.0.3.ebuild
@@ -0,0 +1,38 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{9..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="A collection of accessible pygments styles"
+HOMEPAGE="
+	https://pypi.org/project/accessible-pygments/
+	https://github.com/Quansight-Labs/accessible-pygments/
+"
+SRC_URI="
+	https://github.com/Quansight-Labs/accessible-pygments/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/pygments-1.5[${PYTHON_USEDEP}]
+"
+
+PATCHES=(
+	"${FILESDIR}/${P}-test-install.patch"
+)
+
+python_test() {
+	# it's more like a demo but at least checks if all themes can
+	# be loaded and run; we can't reasonably compare the results
+	# because they differ by pygments version a lot
+	"${EPYTHON}" test/run_tests.py || die
+}