1 files changed, 49 insertions, 0 deletions
diff --git a/dev-php/PEAR-Crypt_GPG/PEAR-Crypt_GPG-1.6.6.ebuild b/dev-php/PEAR-Crypt_GPG/PEAR-Crypt_GPG-1.6.6.ebuild
new file mode 100644
index 000000000000..0315abb14ede
--- /dev/null
+++ b/dev-php/PEAR-Crypt_GPG/PEAR-Crypt_GPG-1.6.6.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PN="${PN/PEAR-/}"
+MY_PV="${PV/_/}"
+MY_P="${MY_PN}-${MY_PV}"
+
+DESCRIPTION="PHP interface to the GNU Privacy Guard (GnuPG)"
+HOMEPAGE="https://pear.php.net/package/Crypt_GPG"
+SRC_URI="http://download.pear.php.net/package/${MY_P}.tgz"
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="app-crypt/gnupg
+	dev-lang/php:*[posix,unicode]
+	dev-php/PEAR-Console_CommandLine
+	dev-php/PEAR-Exception"
+BDEPEND="test? ( ${RDEPEND} <dev-php/phpunit-9 )"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	default
+
+	sed -i "s|@bin-dir@|${EPREFIX}/usr/bin|" Crypt/GPG/Engine.php || die
+	sed -i "s|@package-name@|${MY_PN}|" Crypt/GPG/PinEntry.php || die
+	sed -i "s|@data-dir@|${EPREFIX}/usr/share|" Crypt/GPG/PinEntry.php || die
+}
+
+src_test() {
+	local -x GNUPGHOME="${HOME}"
+	phpunit --verbose tests/ || die "test suite failed"
+}
+
+src_install() {
+	dodoc README.md
+	dobin scripts/crypt-gpg-pinentry
+
+	insinto "/usr/share/${MY_PN}"
+	doins -r data
+
+	insinto /usr/share/php
+	doins -r Crypt
+}