1 files changed, 46 insertions, 0 deletions
diff --git a/dev-lua/say/say-1.4.1.ebuild b/dev-lua/say/say-1.4.1.ebuild
new file mode 100644
index 000000000000..b17a4c9fa4d1
--- /dev/null
+++ b/dev-lua/say/say-1.4.1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( lua5-{1..4} luajit )
+
+inherit lua
+
+DESCRIPTION="Lua String Hashing/Indexing Library"
+HOMEPAGE="https://github.com/lunarmodules/say"
+SRC_URI="https://github.com/lunarmodules/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="test"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+RDEPEND="${LUA_DEPS}"
+
+BDEPEND="
+	virtual/pkgconfig
+	test? ( dev-lua/busted[${LUA_USEDEP}] )
+	${RDEPEND}
+"
+
+lua_src_test() {
+	busted --lua=${ELUA} || die
+}
+
+src_test() {
+	lua_foreach_impl lua_src_test
+}
+
+lua_src_install() {
+	insinto $(lua_get_lmod_dir)/say
+	doins src/say/init.lua
+
+	einstalldocs
+}
+
+src_install() {
+	lua_foreach_impl lua_src_install
+}