7 files changed, 360 insertions, 2 deletions
diff --git a/dev-libs/Manifest.gz b/dev-libs/Manifest.gz
index 5a0d1bf03b45..723a3a317c78 100644
--- a/dev-libs/Manifest.gz
+++ b/dev-libs/Manifest.gz
diff --git a/dev-libs/apache-arrow/Manifest b/dev-libs/apache-arrow/Manifest
index bba9158b1059..5e6fea4b10c0 100644
--- a/dev-libs/apache-arrow/Manifest
+++ b/dev-libs/apache-arrow/Manifest
@@ -1,7 +1,11 @@
 AUX apache-arrow-11.0.0-shared-lz4.patch 456 BLAKE2B b6c8263ac0cf52e49004836ebd10095aa35e5261265f273d7c22dfc6b7a90ceae5882b9c4de51674f11e8b96e84f881141212e197a80dea9db567da7c033a3ea SHA512 11fab04e1c1da46b6407c52a3bfed12e7bffc36046dd8dc379d1a368010f01eaf7b5f791ecb9fb4d15dd778106b401663ea8c1aceb80e799201b71837c18203f
 AUX apache-arrow-14.0.1-gcc14.patch 336 BLAKE2B 22517d03395a26f2a5089693e575cee794005d752b5531b436780c46d2fd7753cca7e7c129ee0a6699990afac2411892d64bb313bd1a370a7e9d496dcfd2f07c SHA512 8d22b1cafdb83933921e161cb12d2cc14c0244cfa570e52ec3c4061ab447c89469c1812ef94e0aba3a3fa862db6068d1c7ab098704ff03b06ef30873d5618e4d
 DIST apache-arrow-14.0.1.tar.gz 20968461 BLAKE2B 01a4269f98ba2a4de1d6bc29f43a4e97132f8b7bdb3c3d022e0c0ba498527003e8bec0ea0b054f19ae54749f45fe39675f651f6c9e34e815df5a9b9926512431 SHA512 31d19f0ca80349f63db74bae813256b47907f85725a9bf01ef6f32406e79828ebb4701faedb52696b6a5b3bb89ad4e136485fd5eb35d396dd42147c11d4d2713
+DIST apache-arrow-14.0.2.tar.gz 20969982 BLAKE2B 9df119fca564a4140d1143a1ac0614831e4f80846d43439d011b8ca7f5e77461005c96b9430b6dd7ce0ba7496b879a8abc9ffa372e6b455c317abeebb16ae8e4 SHA512 dd6cf6cbb817a48ef5275bb409367e5904526a3c16a17a37ea75101085ea19a71ba6bf936a6f099012e7c528811db1728ef2f14dcb16a1056a22088839280ce0
 DIST apache-arrow-arrow-data-14.0.1.tar.gz 3570422 BLAKE2B df1f8d1c4e321ca0abdce598b09945aa9e63114199e7f2eb0fc549323dadf703b917efd90c04a2d540d763a44128d76c6ee12788a983d4b9536d04297316b656 SHA512 0be19960b0d22fc2e07bf84f11148e69d6fa82f10627eb2a5e4b762b1d4cf4e151a57c5a1dc761d6d8ed29881ea589e4cfe0cd47d5c7cbf7b6107143b4a45e82
+DIST apache-arrow-arrow-data-14.0.2.tar.gz 3570422 BLAKE2B df1f8d1c4e321ca0abdce598b09945aa9e63114199e7f2eb0fc549323dadf703b917efd90c04a2d540d763a44128d76c6ee12788a983d4b9536d04297316b656 SHA512 0be19960b0d22fc2e07bf84f11148e69d6fa82f10627eb2a5e4b762b1d4cf4e151a57c5a1dc761d6d8ed29881ea589e4cfe0cd47d5c7cbf7b6107143b4a45e82
 DIST apache-arrow-parquet-data-14.0.1.tar.gz 1013835 BLAKE2B cb4e544b6588ddad503f9692ee2eee5d4f1e931f10654b7253e11ffd2feb4c957dec047a1b1644c1f1538a3bf7ea726e5a9ae9b7d0c3bb0d55d27f088b5c5be3 SHA512 d4c2af20d6a88c1beb44770982f4aa324ea4ee375e8f556339074875af15c48f4398d972c1eec35eba5d209e9e62df4bdbf73ebc8148a7bb05ffa2d69c97df61
+DIST apache-arrow-parquet-data-14.0.2.tar.gz 1013835 BLAKE2B cb4e544b6588ddad503f9692ee2eee5d4f1e931f10654b7253e11ffd2feb4c957dec047a1b1644c1f1538a3bf7ea726e5a9ae9b7d0c3bb0d55d27f088b5c5be3 SHA512 d4c2af20d6a88c1beb44770982f4aa324ea4ee375e8f556339074875af15c48f4398d972c1eec35eba5d209e9e62df4bdbf73ebc8148a7bb05ffa2d69c97df61
 EBUILD apache-arrow-14.0.1.ebuild 2870 BLAKE2B 0eb52053da7b1dce11063a45bdf7490017195ad9112d85e6ccdd977a6a2479b4115044f3de0ecd4cc2a2a41e46079267af7ddd7b23ab94bb2f5e4674892c862a SHA512 bdc34ccd49ee75bc7928424ff7cc9b36b39889bfcd3a0369a01b3fd151ec54caaf57378f71fee11748ea1cd395fc2ea88f7ae501ac6fdb107208f5001b80c202
+EBUILD apache-arrow-14.0.2.ebuild 2878 BLAKE2B 19a0e422eca629a8a19152cf21f411b0780ccde65e1b91b1120177d3e360eee08d7652d6e8858fa03eb355adcd9aa584c8568ee43d65e57666c440de91f0168c SHA512 f076058e7ebba34e484a6226ddb44fdd34e3959aebfbfbc1e827b7c435b534cea458561949f16f085055aa4eee97d5973b36b208f645342aae0530ec7a250001
 MISC metadata.xml 804 BLAKE2B 147cae82bbb858c9a443246c0a75d71551cd8848f995f06b3c34e59bb14b70c7e5c45aa4322d74b558a685a13cdf638c39f5834b5f8ec688b56857e0c3a203b6 SHA512 d315cdb2a44df6d71e9d44a87643c081663a3e82f33d97ded812ebda2f65cc45aad978fd2bed34d26ea6ae58a1157243ee0ff39bcaafafbae6ff212024722336
diff --git a/dev-libs/apache-arrow/apache-arrow-14.0.2.ebuild b/dev-libs/apache-arrow/apache-arrow-14.0.2.ebuild
new file mode 100644
index 000000000000..32e5b4c1728b
--- /dev/null
+++ b/dev-libs/apache-arrow/apache-arrow-14.0.2.ebuild
@@ -0,0 +1,124 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+ARROW_DATA_GIT_HASH=d2c73bf78246331d8e58b6f11aa8aa199cbb5929
+PARQUET_DATA_GIT_HASH=b2e7cc755159196e3a068c8594f7acbaecfdaaac
+
+DESCRIPTION="A cross-language development platform for in-memory data."
+HOMEPAGE="https://arrow.apache.org/"
+SRC_URI="
+	mirror://apache/arrow/arrow-${PV}/${P}.tar.gz
+	test? (
+		https://github.com/apache/parquet-testing/archive/${PARQUET_DATA_GIT_HASH}.tar.gz
+			-> ${PN}-parquet-data-${PV}.tar.gz
+		https://github.com/apache/arrow-testing/archive/${ARROW_DATA_GIT_HASH}.tar.gz
+			-> ${PN}-arrow-data-${PV}.tar.gz
+	)
+"
+S="${WORKDIR}/${P}/cpp"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="brotli bzip2 compute dataset +json lz4 parquet re2 snappy ssl test zlib zstd"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	brotli? ( app-arch/brotli:= )
+	bzip2? ( app-arch/bzip2:= )
+	compute? ( dev-libs/libutf8proc:= )
+	dataset? (
+		dev-libs/libutf8proc:=
+		re2? ( dev-libs/re2:= )
+	)
+	lz4? ( app-arch/lz4:= )
+	parquet? (
+		dev-libs/libutf8proc:=
+		dev-libs/thrift:=
+		ssl? ( dev-libs/openssl:= )
+	)
+	snappy? ( app-arch/snappy:= )
+	zlib? ( sys-libs/zlib:= )
+	zstd? ( app-arch/zstd:= )
+"
+DEPEND="${RDEPEND}
+	dev-cpp/xsimd
+	>=dev-libs/boost-1.81.0
+	json? ( dev-libs/rapidjson )
+	test? (
+		dev-cpp/gflags
+		dev-cpp/gtest
+	)
+"
+
+REQUIRED_USE="
+	test? (
+		json
+		parquet? ( zstd )
+	)
+	ssl? ( json )
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-11.0.0-shared-lz4.patch"
+	"${FILESDIR}"/${PN}-14.0.1-gcc14.patch
+)
+
+src_prepare() {
+	# use Gentoo CXXFLAGS, specify docdir at src_configure.
+	sed -i \
+		-e '/SetupCxxFlags/d' \
+		-e '/set(ARROW_DOC_DIR.*)/d' \
+		CMakeLists.txt \
+		|| die
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DARROW_BUILD_STATIC=OFF
+		-DARROW_BUILD_TESTS=$(usex test)
+		-DARROW_COMPUTE=$(usex compute)
+		-DARROW_CSV=ON
+		-DARROW_DATASET=$(usex dataset)
+		-DARROW_DEPENDENCY_SOURCE=SYSTEM
+		-DARROW_DOC_DIR=share/doc/${PF}
+		-DARROW_FILESYSTEM=ON
+		-DARROW_HDFS=ON
+		-DARROW_JEMALLOC=OFF
+		-DARROW_JSON=$(usex json)
+		-DARROW_PARQUET=$(usex parquet)
+		-DPARQUET_REQUIRE_ENCRYPTION=$(usex ssl)
+		-DARROW_USE_CCACHE=OFF
+		-DARROW_USE_SCCACHE=OFF
+		-DARROW_WITH_BROTLI=$(usex brotli)
+		-DARROW_WITH_BZ2=$(usex bzip2)
+		-DARROW_WITH_LZ4=$(usex lz4)
+		-DARROW_WITH_RE2=$(usex re2)
+		-DARROW_WITH_SNAPPY=$(usex snappy)
+		-DARROW_WITH_ZLIB=$(usex zlib)
+		-DARROW_WITH_ZSTD=$(usex zstd)
+		-DCMAKE_CXX_STANDARD=17
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	export PARQUET_TEST_DATA="${WORKDIR}/parquet-testing-${PARQUET_DATA_GIT_HASH}/data"
+	export ARROW_TEST_DATA="${WORKDIR}/arrow-testing-${ARROW_DATA_GIT_HASH}/data"
+	cmake_src_test
+}
+
+src_install() {
+	cmake_src_install
+	if use test; then
+		cd "${D}"/usr/$(get_libdir)
+		rm -r cmake/ArrowTesting || die
+		rm libarrow_testing* || die
+		rm pkgconfig/arrow-testing.pc || die
+	fi
+}
diff --git a/dev-libs/botan/Manifest b/dev-libs/botan/Manifest
index 9a6e4d645a92..b55f0158d65f 100644
--- a/dev-libs/botan/Manifest
+++ b/dev-libs/botan/Manifest
@@ -8,4 +8,5 @@ DIST Botan-3.2.0.tar.xz.asc 488 BLAKE2B f7bc716dd18eedf35928933e22c75de3d2731330
 EBUILD botan-2.19.3-r2.ebuild 4812 BLAKE2B 7d60b4ab89099aaac8c8f8a4c7517b07e9b951511afc4436d5bcd93f79f996dff82e31a981211e9f7035cf90a20a701df640cf288b3f03da33e30bcf6553b26a SHA512 7db8932f965443ad0a46ab77adb35bc3db1dfaefe82f76f98f8c670b76c0351ad28306204ce278bb58d4c0912d29394963accd082c2f8097487f2c57af2b356c
 EBUILD botan-3.1.1.ebuild 5693 BLAKE2B 0fc42ff9c45b42edbc0797db23cbcbc2b3369c8a263fa692f6ce62890b9fd28388b910680c37a623472c6aa83c0ee7e883e48ef6e95d584a619da54e842aced2 SHA512 30324195f2c38bf7508954c3941083386d92f1a31ceae76628783d72de99d7caae8a751b03d9478e16366ffe353f9ef3ccb935c101bf570b0d8d50eb03b5d83d
 EBUILD botan-3.2.0-r1.ebuild 5955 BLAKE2B e2664dcb86942ca4f8924c5b327778c16120fab97883e05c5a50145e56c5154bdd6eff06616c8f1706e5fecf40d4f87e0c5512e628f88f224fa250d15c8b0708 SHA512 81ccdaa911b1e29261c6ea276dd6ac1675f570d885a02254714878fda3e1aff47aa342607c43f40b449232dceabdafd25ff73ad6d70d3f040bc49d0052f385b2
+EBUILD botan-3.2.0-r2.ebuild 5980 BLAKE2B 7dfa6ef02c573b96a9e8df3dbdf823b69343f212f03a3f36557ab214286ce2e51ab0bb514ff2f45827eeaa25c8184cf9d71ddbe9cbf1b3d64fb6c45daff6f294 SHA512 1ae769c23dd7b112e08cfe2fc7504517b9e05e8f5a0f5b49ede868140231e96b8649d68472c79b5dcd6bd0ce7d64ceba9c6609e6dc35201509708e92d7f11df2
 MISC metadata.xml 587 BLAKE2B 8d46466fee633fda0f81549a6e512e4ef5963eda31d7c882cee2fe2bfae8b0379509f046d0bdfdb1fe9481eea0585f1754753ed6b509c4f922b8fbf9ae089f39 SHA512 258e04098b9db5821a66e38d02ffb195b57378621fd2a549c8892744cf257be857ebf75c8e4a2f041cd267f07c2f1c3a5fca8df61db0538d8282507cf03a029d
diff --git a/dev-libs/botan/botan-3.2.0-r2.ebuild b/dev-libs/botan/botan-3.2.0-r2.ebuild
new file mode 100644
index 000000000000..e159ec4d7ba0
--- /dev/null
+++ b/dev-libs/botan/botan-3.2.0-r2.ebuild
@@ -0,0 +1,229 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/botan.asc
+inherit edo flag-o-matic multiprocessing ninja-utils python-r1 toolchain-funcs verify-sig
+
+MY_P="Botan-${PV}"
+DESCRIPTION="C++ crypto library"
+HOMEPAGE="https://botan.randombit.net/"
+SRC_URI="https://botan.randombit.net/releases/${MY_P}.tar.xz"
+SRC_URI+=" verify-sig? ( https://botan.randombit.net/releases/${MY_P}.tar.xz.asc )"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD-2"
+# New major versions are parallel-installable
+SLOT="$(ver_cut 1)/$(ver_cut 1-2)" # soname version
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~ppc-macos"
+IUSE="doc boost bzip2 lzma python static-libs sqlite test tools zlib"
+RESTRICT="!test? ( test )"
+
+CPU_USE=(
+	cpu_flags_arm_{aes,neon,sha1,sha2}
+	cpu_flags_ppc_altivec
+	cpu_flags_x86_{aes,avx2,popcnt,rdrand,sha,sse2,ssse3,sse4_1,sse4_2}
+)
+
+IUSE+=" ${CPU_USE[@]}"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+# NOTE: Boost is needed at runtime too for the CLI tool.
+DEPEND="
+	boost? ( dev-libs/boost:= )
+	bzip2? ( >=app-arch/bzip2-1.0.5:= )
+	lzma? ( app-arch/xz-utils:= )
+	python? ( ${PYTHON_DEPS} )
+	sqlite? ( dev-db/sqlite:3= )
+	zlib? ( >=sys-libs/zlib-1.2.3:= )
+"
+RDEPEND="
+	${DEPEND}
+	!<dev-libs/botan-2.19.3-r1:2[tools]
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	${NINJA_DEPEND}
+	$(python_gen_any_dep '
+		doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	')
+	|| ( >=sys-devel/gcc-11:* >=sys-devel/clang-14:* )
+	verify-sig? ( sec-keys/openpgp-keys-botan )
+"
+
+# NOTE: Considering patching Botan?
+# Please see upstream's guidance:
+# https://botan.randombit.net/handbook/packaging.html#minimize-distribution-patches
+PATCHES=(
+	"${FILESDIR}"/${P}-ninja.patch
+)
+
+python_check_deps() {
+	use doc || return 0
+	python_has_version "dev-python/sphinx[${PYTHON_USEDEP}]"
+}
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} == binary ]] && return
+
+	# bug #908958
+	if tc-is-gcc && ver_test $(gcc-version) -lt 11 ; then
+		eerror "Botan needs >=gcc-11 or >=clang-14 to compile."
+		eerror "Please upgrade GCC: emerge -v1 sys-devel/gcc"
+		die "GCC version is too old to compile Botan!"
+	elif tc-is-clang && ver_test $(clang-version) -lt 14 ; then
+		eerror "Botan needs >=gcc-11 or >=clang-14 to compile."
+		eerror "Please upgrade Clang: emerge -v1 sys-devel/clang"
+		die "Clang version is too old to compile Botan!"
+	fi
+}
+
+src_configure() {
+	tc-export AR CC CXX
+	python_setup
+
+	local disable_modules=(
+		$(usev !boost 'boost')
+	)
+
+	if [[ -z "${DISABLE_MODULES}" ]] ; then
+		elog "Disabling module(s): ${disable_modules[@]}"
+	fi
+
+	local chostarch="${CHOST%%-*}"
+
+	# Arch specific wrangling
+	local myos=
+	case ${CHOST} in
+		*-darwin*)
+			myos=darwin
+			;;
+		*)
+			myos=linux
+
+			if [[ ${CHOST} == *hppa* ]] ; then
+				chostarch=parisc
+			elif [[ ${ABI} == sparc64 ]] ; then
+				chostarch="sparc64"
+			elif [[ ${ABI} == sparc32 ]] ; then
+				chostarch="sparc32"
+			fi
+			;;
+	esac
+
+	local pythonvers=()
+	if use python ; then
+		_append() {
+			pythonvers+=( ${EPYTHON/python/} )
+		}
+
+		python_foreach_impl _append
+	fi
+
+	local myargs=(
+		# Intrinsics
+		# TODO: x86 RDSEED (new CPU_FLAGS_X86?)
+		# TODO: POWER Crypto (new CPU_FLAGS_PPC?)
+		$(usev !cpu_flags_arm_aes '--disable-armv8crypto')
+		$(usev !cpu_flags_arm_neon '--disable-neon')
+		$(usev !cpu_flags_arm_sha1 '--disable-armv8crypto')
+		$(usev !cpu_flags_arm_sha2 '--disable-armv8crypto')
+		$(usev !cpu_flags_ppc_altivec '--disable-altivec')
+		$(usev !cpu_flags_x86_aes '--disable-aes-ni')
+		$(usev !cpu_flags_x86_avx2 '--disable-avx2')
+		$(usev !cpu_flags_x86_popcnt '--disable-bmi2')
+		$(usev !cpu_flags_x86_rdrand '--disable-rdrand')
+		$(usev !cpu_flags_x86_sha '--disable-sha-ni')
+		$(usev !cpu_flags_x86_sse2 '--disable-sse2')
+		$(usev !cpu_flags_x86_ssse3 '--disable-ssse3')
+		$(usev !cpu_flags_x86_sse4_1 '--disable-sse4.1')
+		$(usev !cpu_flags_x86_sse4_2 '--disable-sse4.2')
+
+		# HPPA's GCC doesn't support SSP
+		$(usev hppa '--without-stack-protector')
+
+		$(use_with boost)
+		$(use_with bzip2)
+		$(use_with doc documentation)
+		$(use_with doc sphinx)
+		$(use_with lzma)
+		$(use_enable static-libs static-library)
+		$(use_with sqlite sqlite3)
+		$(use_with zlib)
+
+		--build-tool=ninja
+		--cpu=${chostarch}
+		--docdir=share/doc
+		--disable-modules=$(IFS=","; echo "${disable_modules[*]}")
+		--distribution-info="Gentoo ${PVR}"
+		--libdir="$(get_libdir)"
+		# Avoid collisions between slots for tools (bug #905700)
+		--program-suffix=$(ver_cut 1)
+
+		# Don't install Python bindings automatically
+		# (do it manually later in the right place)
+		# bug #723096
+		--no-install-python-module
+
+		--os=${myos}
+		--prefix="${EPREFIX}"/usr
+		--with-endian="$(tc-endian)"
+		--with-python-version=$(IFS=","; echo "${pythonvers[*]}")
+	)
+
+	local build_targets=(
+		shared
+		$(usev static-libs static)
+		$(usev tools cli)
+		$(usev test tests)
+	)
+
+	myargs+=(
+		--build-targets=$(IFS=","; echo "${build_targets[*]}")
+	)
+
+	if ( use elibc_glibc || use elibc_musl ) && use kernel_linux ; then
+		myargs+=(
+			--with-os-features=getrandom,getentropy
+		)
+	fi
+
+	local sanitizers=()
+	if is-flagq -fsanitize=address ; then
+		sanitizers+=( address )
+	fi
+	if is-flagq -fsanitize=undefined ; then
+		sanitizers+=( undefined )
+	fi
+	filter-flags '-fsanitize=*'
+	myargs+=(
+		--enable-sanitizers=$(IFS=","; echo "${sanitizers[*]}")
+	)
+
+	edo ${EPYTHON} configure.py --verbose "${myargs[@]}"
+}
+
+src_compile() {
+	eninja
+}
+
+src_test() {
+	LD_LIBRARY_PATH="${S}" edo ./botan-test$(ver_cut 1) --test-threads="$(makeopts_jobs)"
+}
+
+src_install() {
+	DESTDIR="${D}" eninja install
+
+	if [[ -d "${ED}"/usr/share/doc/${P} && ${P} != ${PF} ]] ; then
+		# --docdir in configure controls the parent directory unfortunately
+		mv "${ED}"/usr/share/doc/${P} "${ED}"/usr/share/doc/${PF} || die
+	fi
+
+	# Manually install the Python bindings (bug #723096)
+	if use python ; then
+		python_foreach_impl python_domodule src/python/botan$(ver_cut 1).py
+	fi
+}
diff --git a/dev-libs/libqtxdg/Manifest b/dev-libs/libqtxdg/Manifest
index 6d6dae17f6c8..d3866c6ea4be 100644
--- a/dev-libs/libqtxdg/Manifest
+++ b/dev-libs/libqtxdg/Manifest
@@ -1,5 +1,5 @@
 DIST libqtxdg-3.11.0.tar.xz 71688 BLAKE2B df5f9ebe6d964a23c89402419e4b6e27812a25d96d065e64c05348fe833e2c27c06e11260c8c58999b232eaf154404549100b81325e02ec7c10eaa40d68ff4cd SHA512 494140fa35e184c128c851f06501b5c62324a796d3f61ed47b750dbdffff756c1a42240d4458797e2f2f01c9b06b997f0fbfc76fe7f99866f7cad084ac1342f7
 DIST libqtxdg-3.12.0.tar.xz 71684 BLAKE2B 909fe97ccd8815d9d923d440abef9f0e9cf28fa8e18220f6998e69ff17a1bbb28b37c734758c01cb0a9537464fb0dd2f38b1f61640fd8468c30f8aac57e62106 SHA512 9db46b0dddb027a24e1c19a2e3679014735cc246f15d32bc5fb9e778cd7d8fb57c9b105f819091308002f0a2eff8269920ecc0d7bd5ce8a01fbaf0b37e61a76e
 EBUILD libqtxdg-3.11.0.ebuild 1193 BLAKE2B 60055e4009b7900a4d7d489dacb32ecf1f5a0efca9f9d8540131e550f9975c6ba7df6f53721c4dc92616153d00eee7560be39eadb6dfc0bc4c08d4c74fe7ea46 SHA512 772af66e9b8dc875bdbd4dd6fe30e631b2326574487d191e86fa3d967419b14d82dc06cfec81b0e85b596f72d83d24ebf7c4ee7dff50f809be99726846799f5c
-EBUILD libqtxdg-3.12.0.ebuild 1195 BLAKE2B faea145456d0674cb6e04adbf3241432803892ec8ee73758d14033f702a2c0e9cf74ca3a60ee10558713254f623b2b307baddfd9c29cfe66fb84984643929382 SHA512 4263c1d02c7c5cd0c2bef58fe187a43e25e02458638516117016721b01bace149341bf84c4a2212b8a61f307916b805d804ddf82c8db0e8f187f5f3d233614a4
+EBUILD libqtxdg-3.12.0.ebuild 1194 BLAKE2B 7e69f65b177da036b30d0ff27b1b2aeb0c7024c80f7f43c98eb54aa3fc0ef4845cc41dc0bf256dd54cb9da0ebf08a48a83cd2ec973b12a3a80f517ac29fcdf9f SHA512 f0cc49143eb76cadeb2c688de19b0f0fb98e8ab27ec86b4e859777f4d432261791f1cc367bd8413993c77b9f7fe1b04f1333a4d0d6e54b60d813fa2548156e9b
 MISC metadata.xml 423 BLAKE2B 6205fdbb66e8286d35f33cd497befee8128750eecf8ca674c578937ae1fdd34f4036e91c7719e9333c78a4a5a6fdd3082b7ffc6fcfb839f2d7cb9218ba92a837 SHA512 0097795563b8aba727267461be9ff727fc738c1efa182ba9c8d9e15c7d334efc41fae1c402b09315ad41c8af179f9ad1dfa1d0b055cfd072b2e013227c36edc4
diff --git a/dev-libs/libqtxdg/libqtxdg-3.12.0.ebuild b/dev-libs/libqtxdg/libqtxdg-3.12.0.ebuild
index 7fd18a68ab8d..01da5c1f7e5c 100644
--- a/dev-libs/libqtxdg/libqtxdg-3.12.0.ebuild
+++ b/dev-libs/libqtxdg/libqtxdg-3.12.0.ebuild
@@ -13,7 +13,7 @@ if [[ ${PV} == *9999 ]]; then
 	EGIT_REPO_URI="https://github.com/lxqt/${PN}.git"
 else
 	SRC_URI="https://github.com/lxqt/${PN}/releases/download/${PV}/${P}.tar.xz"
-	KEYWORDS="amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+	KEYWORDS="amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv x86"
 fi
 
 LICENSE="LGPL-2.1+ Nokia-Qt-LGPL-Exception-1.1"