1 files changed, 0 insertions, 82 deletions
diff --git a/dev-libs/zziplib/zziplib-0.13.62-r2.ebuild b/dev-libs/zziplib/zziplib-0.13.62-r2.ebuild
deleted file mode 100644
index 6b1da7bf50b6..000000000000
--- a/dev-libs/zziplib/zziplib-0.13.62-r2.ebuild
+++ /dev/null
@@ -1,82 +0,0 @@
-# Copyright 1999-2018 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=5
-
-PYTHON_COMPAT=( python2_7 )
-
-inherit libtool eutils flag-o-matic python-any-r1
-
-DESCRIPTION="Lightweight library for extracting data from files archived in a single zip file"
-HOMEPAGE="http://zziplib.sourceforge.net/"
-SRC_URI="mirror://sourceforge/zziplib/${P}.tar.bz2"
-
-LICENSE="|| ( LGPL-2.1 MPL-1.1 )"
-SLOT="0"
-KEYWORDS="alpha amd64 arm arm64 hppa ia64 ~mips ppc ppc64 s390 ~sh sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
-IUSE="doc sdl static-libs test"
-
-RDEPEND="
-	sys-libs/zlib
-	sdl? ( >=media-libs/libsdl-1.2.6 )"
-DEPEND="${RDEPEND}
-	${PYTHON_DEPS}
-	virtual/pkgconfig
-	test? ( app-arch/zip )"
-
-src_prepare() {
-	epatch "${FILESDIR}"/${PN}-0.13.49-SDL-test.patch
-
-	python_fix_shebang .
-
-	# workaround AX_CREATE_PKGCONFIG_INFO bug #353195
-	sed -i \
-		-e '/ax_create_pkgconfig_ldflags/s:$LDFLAGS::' \
-		-e '/ax_create_pkgconfig_cppflags/s:$CPPFLAGS::' \
-		configure || die
-
-	# zziplib tries to install backwards compat symlinks we dont want
-	sed -i -e '/^zzip-postinstall:/s|$|\ndisable-this:|' Makefile.in || die
-	sed -i -e '/^install-exec-hook:/s|$|\ndisable-this:|' zzip/Makefile.in || die
-
-	elibtoolize
-
-	# Do an out-of-tree build as their configure will do it automatically
-	# otherwise and that can lead to funky errors. #492816
-	mkdir -p build
-}
-
-src_configure() {
-	cd "${S}"/build
-
-	append-flags -fno-strict-aliasing # bug reported upstream
-	export ac_cv_path_XMLTO= # man pages are bundled in .tar's
-
-	# Disable aclocal probing as the default path works #449156
-	ECONF_SOURCE=${S} \
-	ACLOCAL=true \
-	econf \
-		$(use_enable sdl) \
-		$(use_enable static-libs static)
-	MAKEOPTS+=' -C build'
-}
-
-src_test() {
-	# need this because `make test` will always return true
-	# tests fail with -j > 1 (bug #241186)
-	emake -j1 check
-}
-
-src_install() {
-	default
-	# fowners fails when we don't have enough permissions (Prefix)
-	if [[ ${EUID} == 0 ]] ; then
-		fowners -R root /usr/share/man #321975
-	fi
-
-	prune_libtool_files
-
-	if use doc ; then
-		dohtml -r docs/*
-	fi
-}