1 files changed, 53 insertions, 0 deletions
diff --git a/dev-libs/mongo-c-driver/mongo-c-driver-0.8.1-r1.ebuild b/dev-libs/mongo-c-driver/mongo-c-driver-0.8.1-r1.ebuild
new file mode 100644
index 000000000000..764dce23aa5c
--- /dev/null
+++ b/dev-libs/mongo-c-driver/mongo-c-driver-0.8.1-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="5"
+PYTHON_COMPAT=( python2_7 )
+
+inherit base flag-o-matic multilib python-any-r1 toolchain-funcs
+
+DESCRIPTION="C Driver for MongoDB"
+HOMEPAGE="http://www.mongodb.org/ https://github.com/mongodb/mongo-c-driver"
+SRC_URI="https://github.com/mongodb/${PN}/tarball/v${PV/_/} -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ppc ~x86"
+IUSE="doc static-libs"
+
+# tests fails to build
+RESTRICT="test"
+
+RDEPEND=""
+DEPEND="${PYTHON_DEPS}
+	doc? ( $(python_gen_any_dep 'dev-python/sphinx[${PYTHON_USEDEP}]') )
+"
+PATCHES=( "${FILESDIR}/${PV}-api-version.diff" )
+
+python_check_deps() {
+	if use doc; then
+		has_version "dev-python/sphinx[${PYTHON_USEDEP}]"
+	fi
+}
+
+src_unpack() {
+	unpack ${A}
+	mv *-${PN}-* "${S}"
+}
+
+src_compile() {
+	append-cflags -D_POSIX_C_SOURCE=200112L
+	tc-export CC
+	emake
+	use doc && make -C docs/source/sphinx html
+}
+
+src_install() {
+	emake install \
+		INSTALL_LIBRARY_PATH="${D}/usr/$(get_libdir)" \
+		INSTALL_INCLUDE_PATH="${D}/usr/include"
+
+	use static-libs || find "${ED}" -name '*.a' -exec rm -f {} +
+
+	use doc && dohtml -r docs/source/sphinx/build/html/*
+}