1 files changed, 37 insertions, 0 deletions
diff --git a/dev-libs/mimalloc/mimalloc-2.1.4.ebuild b/dev-libs/mimalloc/mimalloc-2.1.4.ebuild
new file mode 100644
index 000000000000..bd26f566a18c
--- /dev/null
+++ b/dev-libs/mimalloc/mimalloc-2.1.4.ebuild
@@ -0,0 +1,37 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake-multilib
+
+DESCRIPTION="A compact general purpose allocator with excellent performance"
+HOMEPAGE="https://github.com/microsoft/mimalloc"
+SRC_URI="https://github.com/microsoft/mimalloc/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0/2"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~sparc ~x86"
+IUSE="hardened test valgrind"
+RESTRICT="!test? ( test )"
+
+DEPEND="valgrind? ( dev-debug/valgrind )"
+
+src_configure() {
+	local mycmakeargs=(
+		-DMI_SECURE=$(usex hardened)
+		-DMI_INSTALL_TOPLEVEL=ON
+		-DMI_BUILD_TESTS=$(usex test)
+		-DMI_BUILD_OBJECT=OFF
+		-DMI_BUILD_STATIC=OFF
+		-DMI_TRACK_VALGRIND=$(usex valgrind)
+
+		# Bug #923177
+		# find_library(... atomic) appears to not work. Fall back to -latomic
+		-DMI_USE_LIBATOMIC=ON
+
+		-DMI_LIBC_MUSL=$(usex elibc_musl)
+	)
+
+	cmake-multilib_src_configure
+}