1 files changed, 56 insertions, 0 deletions
diff --git a/dev-libs/libunibreak/libunibreak-4.0.ebuild b/dev-libs/libunibreak/libunibreak-4.0.ebuild
new file mode 100644
index 000000000000..ede6eebde7e0
--- /dev/null
+++ b/dev-libs/libunibreak/libunibreak-4.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit versionator
+
+DESCRIPTION="Line and word breaking library"
+HOMEPAGE="http://vimgadgets.sourceforge.net/libunibreak/"
+SRC_URI="https://github.com/adah1972/${PN}/releases/download/${PN}_$(replace_all_version_separators '_')/${P}.tar.gz"
+
+LICENSE="ZLIB"
+SLOT="0"
+KEYWORDS="amd64 ~arm ~ppc x86"
+IUSE="doc +man static-libs"
+
+# Tests require internet access to www.unicode.org
+RESTRICT="test"
+
+DEPEND="man? ( app-doc/doxygen )"
+RDEPEND="!dev-libs/liblinebreak"
+
+src_prepare() {
+	if use man; then
+		echo 'GENERATE_MAN=YES' >> Doxyfile || die
+		echo 'GENERATE_HTML=NO' >> Doxyfile || die
+	fi
+	default
+}
+
+src_configure() {
+	econf $(use_enable static-libs static)
+}
+
+src_compile() {
+	default
+	if use man; then
+		doxygen || die 'doxygen failed'
+		pushd "${S}"/doc/man > /dev/null
+		mv man3 x || die
+		mkdir man3 || die
+		for h in graphemebreak linebreak linebreakdef unibreakbase unibreakdef wordbreak; do
+			mv x/${h}.h.3 man3/ || die "man ${h} not found"
+		done
+		rm -rf x || die
+		popd > /dev/null
+	fi
+}
+
+src_install() {
+	use doc && HTML_DOCS=( doc/html/. )
+	default
+	find "${D}" -name '*.la' -delete || die
+	if use man; then
+		doman doc/man/man3/*.3
+	fi
+}