1 files changed, 77 insertions, 0 deletions
diff --git a/dev-libs/libpeas/libpeas-1.26.0.ebuild b/dev-libs/libpeas/libpeas-1.26.0.ebuild
new file mode 100644
index 000000000000..c7ca33771f79
--- /dev/null
+++ b/dev-libs/libpeas/libpeas-1.26.0.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python{3_6,3_7,3_8} )
+
+inherit gnome.org meson python-single-r1 vala virtualx xdg
+
+DESCRIPTION="A GObject plugins library"
+HOMEPAGE="https://developer.gnome.org/libpeas/stable/"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+IUSE="glade +gtk gtk-doc lua luajit +python vala"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	>=dev-libs/glib-2.38:2
+	>=dev-libs/gobject-introspection-1.39:=
+	gtk? ( >=x11-libs/gtk+-3.0.0:3[introspection] )
+	glade? ( >=dev-util/glade-3.9.1:3.10 )
+	lua? (
+		>=dev-lua/lgi-0.9.0
+		luajit? ( >=dev-lang/luajit-2:2 )
+		!luajit? ( =dev-lang/lua-5.1*:0 ) )
+	python? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep '
+			>=dev-python/pygobject-3.2:3[${PYTHON_MULTI_USEDEP}]
+		')
+	)
+"
+DEPEND="${RDEPEND}
+	dev-util/glib-utils
+	gtk-doc? ( >=dev-util/gtk-doc-1.11
+		app-text/docbook-xml-dtd:4.3 )
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	# Gentoo-specific lua tweak hack
+	"${FILESDIR}"/${PV}-lua.patch
+)
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	xdg_src_prepare
+	use vala && vala_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature $(usex lua !luajit lua) lua51)
+		$(meson_feature $(usex lua luajit lua) luajit)
+		-Dpython2=false
+		$(meson_use python python3)
+		# introspection was always enabled in autotools; would need readiness by consumers
+		# to USE flag it, but most need it for python plugins anyways
+		-Dintrospection=true
+		$(meson_use vala vapi)
+		$(meson_use gtk widgetry)
+		$(meson_use glade glade_catalog)
+		-Ddemos=false
+		$(meson_use gtk-doc gtk_doc)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}