1 files changed, 55 insertions, 0 deletions
diff --git a/dev-libs/libixion/libixion-0.14.1.ebuild b/dev-libs/libixion/libixion-0.14.1.ebuild
new file mode 100644
index 000000000000..51e6e3935b81
--- /dev/null
+++ b/dev-libs/libixion/libixion-0.14.1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+EGIT_REPO_URI="https://gitlab.com/ixion/ixion.git"
+
+PYTHON_COMPAT=( python{3_4,3_5,3_6} )
+
+[[ ${PV} == 9999 ]] && GITECLASS="git-r3 autotools"
+inherit python-single-r1 ${GITECLASS}
+unset GITECLASS
+
+DESCRIPTION="General purpose formula parser & interpreter"
+HOMEPAGE="https://gitlab.com/ixion/ixion"
+[[ ${PV} == 9999 ]] || SRC_URI="https://kohei.us/files/ixion/src/${P}.tar.xz"
+
+LICENSE="MIT"
+SLOT="0/0.14" # based on SONAME of libixion.so
+[[ ${PV} == 9999 ]] || \
+KEYWORDS=""
+# KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~x86"
+IUSE="debug python static-libs +threads"
+
+RDEPEND="
+	dev-libs/boost:=
+	python? ( ${PYTHON_DEPS} )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/mdds-1.4.1:1=
+"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	[[ ${PV} == 9999 ]] && eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable debug) \
+		$(use_enable python) \
+		$(use_enable static-libs static) \
+		$(use_enable threads)
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}