1 files changed, 52 insertions, 0 deletions
diff --git a/dev-libs/libedit/libedit-20190324.3.1.ebuild b/dev-libs/libedit/libedit-20190324.3.1.ebuild
new file mode 100644
index 000000000000..8ed4cd6e2194
--- /dev/null
+++ b/dev-libs/libedit/libedit-20190324.3.1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+inherit autotools multilib-minimal toolchain-funcs usr-ldscript
+
+MY_PV=${PV/./-}
+MY_P=${PN}-${MY_PV}
+
+DESCRIPTION="BSD replacement for libreadline"
+HOMEPAGE="https://thrysoee.dk/editline/"
+SRC_URI="https://thrysoee.dk/editline/${MY_P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="static-libs"
+
+DEPEND=">=sys-libs/ncurses-5.9-r3[static-libs?,${MULTILIB_USEDEP}]
+	!<=sys-freebsd/freebsd-lib-6.2_rc1"
+
+RDEPEND=${DEPEND}
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-20170329.3.1-tinfo.patch"
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" econf \
+		$(use_enable static-libs static) \
+		--enable-widec \
+		--enable-fast-install
+}
+
+multilib_src_install() {
+	emake DESTDIR="${D}" install
+	gen_usr_ldscript -a edit
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	find "${D}" -name '*.la' -delete || die
+	# file collission with sys-libs/readline
+	rm "${ED%/}/usr/share/man/man3/history.3" || die
+}