1 files changed, 43 insertions, 0 deletions
diff --git a/dev-libs/isa-l_crypto/isa-l_crypto-2.24.0.ebuild b/dev-libs/isa-l_crypto/isa-l_crypto-2.24.0.ebuild
new file mode 100644
index 000000000000..5ea355130d4b
--- /dev/null
+++ b/dev-libs/isa-l_crypto/isa-l_crypto-2.24.0.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Intelligent Storage Acceleration Library - cryptographic components"
+HOMEPAGE="https://github.com/intel/isa-l_crypto"
+SRC_URI="https://github.com/intel/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="cpu_flags_x86_avx512f"
+
+# AVX512 support in yasm is still work in progress
+BDEPEND="amd64? (
+	cpu_flags_x86_avx512f? ( >=dev-lang/nasm-2.13 )
+	!cpu_flags_x86_avx512f? ( || (
+		>=dev-lang/nasm-2.11.01
+		>=dev-lang/yasm-1.2.0
+	) )
+)"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.24.0_makefile-no-D.patch
+)
+
+src_prepare() {
+	default
+
+	# isa-l does not support arbitrary assemblers on amd64 (and presumably x86),
+	# it must be either nasm or yasm.
+	use amd64 && unset AS
+
+	eautoreconf
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -delete || die
+}