1 files changed, 42 insertions, 0 deletions
diff --git a/dev-libs/boxfort/boxfort-0.1.1.ebuild b/dev-libs/boxfort/boxfort-0.1.1.ebuild
new file mode 100644
index 000000000000..45a22331a50f
--- /dev/null
+++ b/dev-libs/boxfort/boxfort-0.1.1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{7..10} )
+
+inherit meson python-any-r1
+
+DESCRIPTION="Convenient & cross-platform sandboxing C library"
+HOMEPAGE="https://github.com/Snaipe/BoxFort"
+SRC_URI="https://github.com/Snaipe/BoxFort/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 -riscv ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+DEPEND="test? (
+		$(python_gen_any_dep 'dev-util/cram[${PYTHON_USEDEP}]')
+	)"
+BDEPEND="virtual/pkgconfig"
+
+S="${WORKDIR}/BoxFort-${PV}"
+
+python_check_deps() {
+	use test && has_version "dev-util/cram[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dsamples=$(usex test true false)
+		-Dtests=$(usex test true false)
+	)
+
+	meson_src_configure
+}