1 files changed, 52 insertions, 0 deletions
diff --git a/dev-libs/angelscript/angelscript-2.35.1-r1.ebuild b/dev-libs/angelscript/angelscript-2.35.1-r1.ebuild
new file mode 100644
index 000000000000..d0aa028768b9
--- /dev/null
+++ b/dev-libs/angelscript/angelscript-2.35.1-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs multilib-minimal
+
+DESCRIPTION="A flexible, cross-platform scripting library"
+HOMEPAGE="http://www.angelcode.com/angelscript/"
+SRC_URI="http://www.angelcode.com/angelscript/sdk/files/angelscript_${PV}.zip"
+LICENSE="ZLIB"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="doc static-libs"
+
+BDEPEND="app-arch/unzip"
+
+S="${WORKDIR}/sdk"
+PATCHES=(
+	"${FILESDIR}/0004-Add-as_callfunc_arm64.cpp-to-gnuc-makefile.patch"
+	"${FILESDIR}/0006-Add-as_callfunc_arm_gcc.S-to-gnuc-makefile.patch"
+)
+
+pkg_setup() {
+	tc-export CXX AR RANLIB
+}
+
+src_prepare() {
+	default
+	multilib_copy_sources
+}
+
+multilib_src_compile() {
+	emake -C ${PN}/projects/gnuc shared \
+		  $(use static-libs && echo static)
+}
+
+multilib_src_install() {
+	emake -C ${PN}/projects/gnuc \
+		  DESTDIR="${D}" \
+		  PREFIX="${EPREFIX}"/usr \
+		  LIBDIR_DEST='$(PREFIX)'/$(get_libdir) \
+		  install_header install_shared \
+		  $(use static-libs && echo install_static)
+}
+
+multilib_src_install_all() {
+	if use doc; then
+		docinto html
+		dodoc -r docs/*
+	fi
+}