1 files changed, 45 insertions, 0 deletions
diff --git a/dev-cpp/cairomm/cairomm-1.14.3-r1.ebuild b/dev-cpp/cairomm/cairomm-1.14.3-r1.ebuild
new file mode 100644
index 000000000000..a01304aa8cd0
--- /dev/null
+++ b/dev-cpp/cairomm/cairomm-1.14.3-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson-multilib
+
+DESCRIPTION="C++ bindings for the Cairo vector graphics library"
+HOMEPAGE="https://cairographics.org/cairomm/"
+SRC_URI="https://www.cairographics.org/releases/${P}.tar.xz"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ppc ppc64 ~riscv sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-solaris"
+IUSE="gtk-doc test X"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/libsigc++-2.6.0:2[gtk-doc?,${MULTILIB_USEDEP}]
+	>=x11-libs/cairo-1.12.0[X=,${MULTILIB_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	test? (
+		dev-libs/boost[${MULTILIB_USEDEP}]
+		media-libs/fontconfig[${MULTILIB_USEDEP}]
+	)
+"
+BDEPEND="
+	virtual/pkgconfig
+	gtk-doc? (
+		app-doc/doxygen[dot]
+		dev-lang/perl
+		dev-libs/libxslt
+	)
+"
+
+multilib_src_configure() {
+	local emesonargs=(
+		$(meson_native_use_bool gtk-doc build-documentation)
+		-Dbuild-examples=false
+		$(meson_use test build-tests)
+		-Dboost-shared=true
+	)
+	meson_src_configure
+}