1 files changed, 69 insertions, 0 deletions
diff --git a/app-portage/layman/layman-2.0.0-r3.ebuild b/app-portage/layman/layman-2.0.0-r3.ebuild
new file mode 100644
index 000000000000..dfe874aaa77b
--- /dev/null
+++ b/app-portage/layman/layman-2.0.0-r3.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="5"
+
+PYTHON_COMPAT=( python2_7 pypy )
+PYTHON_REQ_USE="xml(+)"
+
+inherit eutils distutils-r1 prefix
+
+DESCRIPTION="Tool to manage Gentoo overlays"
+HOMEPAGE="http://layman.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ~m68k ~mips ppc ppc64 ~s390 ~sh sparc x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="bazaar cvs darcs +git mercurial subversion test"
+
+DEPEND="test? ( dev-vcs/subversion )"
+
+RDEPEND="
+	bazaar? ( dev-vcs/bzr )
+	cvs? ( dev-vcs/cvs )
+	darcs? ( dev-vcs/darcs )
+	git? ( dev-vcs/git )
+	mercurial? ( dev-vcs/mercurial )
+	subversion? (
+		|| (
+			>=dev-vcs/subversion-1.5.4[http]
+			>=dev-vcs/subversion-1.5.4[webdav-neon]
+			>=dev-vcs/subversion-1.5.4[webdav-serf]
+		)
+	)
+	sys-apps/portage[${PYTHON_USEDEP}]
+	"
+
+python_prepare_all()  {
+	local PATCHES=( "${FILESDIR}"/layman-2.0.0.*.patch )
+	distutils-r1_python_prepare_all
+	eprefixify etc/layman.cfg layman/config.py
+}
+
+python_test() {
+	for suite in layman/tests/{dtest,external}.py ; do
+		PYTHONPATH="." "${PYTHON}" ${suite} \
+				|| die "test suite '${suite}' failed"
+	done
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	insinto /etc/layman
+	doins etc/layman.cfg
+
+	doman doc/layman.8
+	dohtml doc/layman.8.html
+
+	keepdir /var/lib/layman
+	keepdir /etc/layman/overlays
+}
+
+pkg_postinst() {
+	# now run layman's update utility
+	einfo "Running layman-updater..."
+	"${EROOT}"/usr/bin/layman-updater
+	einfo
+}