1 files changed, 38 insertions, 0 deletions
diff --git a/app-misc/ddcui/ddcui-0.1.2-r1.ebuild b/app-misc/ddcui/ddcui-0.1.2-r1.ebuild
new file mode 100644
index 000000000000..dd9daddef09b
--- /dev/null
+++ b/app-misc/ddcui/ddcui-0.1.2-r1.ebuild
@@ -0,0 +1,38 @@
+# Copyright 2019-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake desktop xdg
+
+DESCRIPTION="Graphical user interface for ddcutil - control monitor settings"
+HOMEPAGE="https://www.ddcutil.com/ddcui_main/"
+SRC_URI="https://github.com/rockowitz/ddcui/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+KEYWORDS="~amd64"
+LICENSE="GPL-2+"
+SLOT="0"
+
+DEPEND="
+	dev-libs/glib
+	>=app-misc/ddcutil-0.9.9:0/3
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qthelp:5
+	dev-qt/qtwidgets:5
+"
+RDEPEND="${DEPEND}
+	virtual/freedesktop-icon-theme
+"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	# move docs to correct dir
+	sed -i -e "s%share/doc/ddcui%share/doc/${PF}%g" CMakeLists.txt || die
+	cmake_src_prepare
+}
+
+src_install() {
+	cmake_src_install
+	make_desktop_entry ddcui "Monitor Settings" preferences-desktop-display Settings
+}