1 files changed, 57 insertions, 0 deletions
diff --git a/app-i18n/zhcon/zhcon-0.2.6-r3.ebuild b/app-i18n/zhcon/zhcon-0.2.6-r3.ebuild
new file mode 100644
index 000000000000..f428d22d614f
--- /dev/null
+++ b/app-i18n/zhcon/zhcon-0.2.6-r3.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+WANT_AUTOMAKE="1.9"
+
+inherit autotools eutils
+
+MY_P="${P/6/5}"
+
+DESCRIPTION="A Fast CJK (Chinese/Japanese/Korean) Console Environment"
+HOMEPAGE="http://zhcon.sourceforge.net/"
+SRC_URI="mirror://sourceforge/zhcon/${MY_P}.tar.gz
+		mirror://sourceforge/zhcon/zhcon-0.2.5-to-0.2.6.diff.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="ggi gpm"
+
+DEPEND="ggi? ( media-libs/libggi[X] )
+	gpm? ( sys-libs/gpm )"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=(
+	"${FILESDIR}"/${P}.sysconfdir.patch
+	"${FILESDIR}"/${P}.configure.in.patch
+	"${FILESDIR}"/${P}+gcc-4.3.patch
+	"${FILESDIR}"/${P}+linux-headers-2.6.26.patch
+	"${FILESDIR}"/${P}-curses.patch
+	"${FILESDIR}"/${P}-amd64.patch
+	"${FILESDIR}"/${P}-automagic-fix.patch
+	"${FILESDIR}"/${P}.make-fix.patch
+)
+
+src_prepare() {
+	epatch "${DISTDIR}"/zhcon-0.2.5-to-0.2.6.diff.gz
+	default
+	for f in $(grep -lir HAVE_GGI_LIB *); do
+		sed -i -e "s/HAVE_GGI_LIB/HAVE_LIBGGI/" "${f}" || die "sed failed"
+	done
+	eautoreconf
+}
+
+src_configure() {
+	econf $(use_with ggi) \
+		$(use_with gpm)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	dodoc AUTHORS ChangeLog README NEWS TODO THANKS
+	dodoc README.BSD README.gpm README.utf8
+}