1 files changed, 70 insertions, 0 deletions
diff --git a/app-i18n/kinput2/kinput2-3.1-r1.ebuild b/app-i18n/kinput2/kinput2-3.1-r1.ebuild
new file mode 100644
index 000000000000..d18b1cdc75d1
--- /dev/null
+++ b/app-i18n/kinput2/kinput2-3.1-r1.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit toolchain-funcs
+
+MY_P="${PN}-v${PV}"
+
+DESCRIPTION="A Japanese input server which supports the XIM protocol"
+HOMEPAGE="http://www.nec.co.jp/canna"
+SRC_URI="ftp://ftp.sra.co.jp/pub/x11/${PN}/${MY_P}.tar.gz"
+
+LICENSE="HPND"
+SLOT="0"
+KEYWORDS="amd64 ppc ppc64 sparc x86"
+IUSE="freewnn"
+
+RDEPEND="x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXaw
+	x11-libs/libXext
+	x11-libs/libXmu
+	x11-libs/libXpm
+	x11-libs/libXt
+	!freewnn? ( app-i18n/canna )
+	freewnn? ( app-i18n/freewnn )"
+DEPEND="${RDEPEND}
+	x11-misc/gccmakedep
+	x11-misc/imake"
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-gentoo.patch
+	"${FILESDIR}"/${PN}-headers.patch
+	"${FILESDIR}"/${PN}-ppc.patch
+	"${FILESDIR}"/${PN}-segfault.patch
+	"${FILESDIR}"/${PN}-wnn.patch
+)
+DOCS=( README NEWS doc/. )
+
+src_prepare() {
+	default
+
+	sed -i "s|^/\* \(#define Use$(usex freewnn Wnn Canna)\) \*/|\1|" ${PN^k}.conf
+}
+
+src_configure() {
+	xmkmf -a || die
+}
+
+src_compile() {
+	emake \
+		CC="$(tc-getCC)" \
+		CDEBUGFLAGS="${CFLAGS}" \
+		LOCAL_LDFLAGS="${LDFLAGS}" \
+		XAPPLOADDIR="${EPREFIX}/usr/share/X11/app-defaults"
+}
+
+src_install() {
+	emake \
+		XAPPLOADDIR="${EPREFIX}/usr/share/X11/app-defaults" \
+		DESTDIR="${D}" \
+		install
+	einstalldocs
+	newman cmd/${PN}.man ${PN}.1
+
+	rm -rf "${ED}"/usr/$(get_libdir)/X11
+}