1 files changed, 48 insertions, 0 deletions
diff --git a/app-i18n/im-freewnn/im-freewnn-0.0.2-r4.ebuild b/app-i18n/im-freewnn/im-freewnn-0.0.2-r4.ebuild
new file mode 100644
index 000000000000..75c8b2d07e01
--- /dev/null
+++ b/app-i18n/im-freewnn/im-freewnn-0.0.2-r4.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools gnome2-utils prefix
+
+DESCRIPTION="Japanese FreeWnn input method module for GTK+2"
+HOMEPAGE="http://bonobo.gnome.gr.jp/~nakai/immodule/"
+SRC_URI="http://bonobo.gnome.gr.jp/~nakai/immodule/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 ppc ppc64 x86"
+
+RDEPEND="
+	app-i18n/freewnn
+	x11-libs/gtk+:2"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-gentoo.patch
+	"${FILESDIR}"/${PN}-headers.patch
+	"${FILESDIR}"/${PN}-wnnenvrc.patch
+)
+
+src_prepare() {
+	default
+	eprefixify ${PN}.c
+
+	eautoreconf
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	gnome2_query_immodules_gtk2
+}
+
+pkg_postrm() {
+	gnome2_query_immodules_gtk2
+}