1 files changed, 42 insertions, 0 deletions
diff --git a/app-i18n/ibus-table/ibus-table-1.5.0-r1.ebuild b/app-i18n/ibus-table/ibus-table-1.5.0-r1.ebuild
new file mode 100644
index 000000000000..313b0d5d4716
--- /dev/null
+++ b/app-i18n/ibus-table/ibus-table-1.5.0-r1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="sqlite(+)"
+
+inherit python-single-r1
+
+DESCRIPTION="Tables engines for IBus"
+HOMEPAGE="https://github.com/ibus/ibus/wiki"
+SRC_URI="https://storage.googleapis.com/google-code-archive-downloads/v2/code.google.com/ibus/${P}.tar.gz"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="nls"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	app-i18n/ibus[python(+),${PYTHON_USEDEP}]
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	virtual/libiconv
+	nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+src_prepare() {
+	python_fix_shebang .
+
+	sed -i \
+		"s/python/${EPYTHON}/" \
+		engine/${PN}-createdb.in \
+		engine/${PN/-/-engine-}.in
+
+	default
+}
+
+src_configure() {
+	econf $(use_enable nls)
+}