1 files changed, 57 insertions, 0 deletions
diff --git a/app-emulation/hercules/hercules-3.13.ebuild b/app-emulation/hercules/hercules-3.13.ebuild
new file mode 100644
index 000000000000..90fb943156a9
--- /dev/null
+++ b/app-emulation/hercules/hercules-3.13.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools flag-o-matic
+
+DESCRIPTION="Hercules System/370, ESA/390 and zArchitecture Mainframe Emulator"
+HOMEPAGE="http://www.hercules-390.eu/"
+SRC_URI="http://downloads.hercules-390.eu/${P}.tar.gz"
+
+LICENSE="QPL-1.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86 ~x64-macos ~x86-macos"
+IUSE="bzip2 custom-cflags +suid"
+
+RDEPEND="
+	dev-libs/libltdl
+	net-libs/libnsl:0=
+	sys-libs/zlib
+	bzip2? ( app-arch/bzip2 )"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.13-htmldir.patch
+	"${FILESDIR}"/${PN}-3.13-unbundle-libltdl.patch
+)
+
+src_prepare() {
+	default
+
+	# delete bundled libltdl, #252716
+	rm ltdl.{c,h} || die
+	eautoreconf
+}
+
+src_configure() {
+	use custom-cflags || strip-flags
+	local -x ac_cv_lib_bz2_BZ2_bzBuffToBuffDecompress=$(usex bzip2)
+	econf \
+		$(use_enable bzip2 cckd-bzip2) \
+		$(use_enable bzip2 het-bzip2) \
+		$(use_enable suid setuid-hercifc) \
+		--enable-custom="Gentoo ${PF}.ebuild" \
+		--disable-optimization
+}
+
+src_install() {
+	default
+	dodoc RELEASE.NOTES
+
+	insinto /usr/share/hercules
+	doins hercules.cnf
+
+	# no static archives
+	find "${D}" -name '*.la' -delete || die
+}