1 files changed, 56 insertions, 0 deletions
diff --git a/app-emacs/yasnippet-snippets/yasnippet-snippets-1.1.ebuild b/app-emacs/yasnippet-snippets/yasnippet-snippets-1.1.ebuild
new file mode 100644
index 000000000000..13490ccc3e98
--- /dev/null
+++ b/app-emacs/yasnippet-snippets/yasnippet-snippets-1.1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit elisp edo
+
+DESCRIPTION="A collection of yasnippet snippets for many languages"
+HOMEPAGE="https://github.com/AndreaCrotti/yasnippet-snippets"
+
+if [[ "${PV}" == *9999* ]] ; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/AndreaCrotti/${PN}.git"
+else
+	SRC_URI="https://github.com/AndreaCrotti/${PN}/archive/${PV}.tar.gz
+		-> ${P}.tar.gz"
+
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+
+RDEPEND="
+	app-emacs/yasnippet
+"
+BDEPEND="
+	${RDEPEND}
+"
+
+PATCHES=( "${FILESDIR}/${PN}-dir.patch" )
+
+DOCS=( README.md )
+SITEFILE="50${PN}-gentoo.el"
+
+src_prepare() {
+	elisp_src_prepare
+
+	sed "s|@SITEETC@|${EPREFIX}${SITEETC}/${PN}|" -i "${PN}.el" || die
+}
+
+src_compile() {
+	elisp_src_compile
+
+	edo ${EMACS} ${EMACSFLAGS} \
+		--eval "(require 'yasnippet)" \
+		--eval "(yas-compile-directory \"${S}/snippets\")"
+}
+
+src_install() {
+	elisp_src_install
+
+	insinto "${SITEETC}/${PN}"
+	doins -r snippets
+}