1 files changed, 53 insertions, 0 deletions
diff --git a/app-editors/notepadqq/notepadqq-1.2.0.ebuild b/app-editors/notepadqq/notepadqq-1.2.0.ebuild
new file mode 100644
index 000000000000..cbebd28ae63f
--- /dev/null
+++ b/app-editors/notepadqq/notepadqq-1.2.0.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit qmake-utils xdg-utils
+
+DESCRIPTION="Notepad++-like editor for Linux"
+HOMEPAGE="http://notepadqq.altervista.org"
+SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtwebkit:5
+	dev-qt/qtwidgets:5
+"
+DEPEND="
+	${RDEPEND}
+	dev-qt/qtsvg:5
+"
+
+src_prepare() {
+	default
+
+	# Silence a QA warning
+	sed '/^OnlyShowIn/d' \
+		-i support_files/shortcuts/notepadqq.desktop \
+		|| die
+}
+
+src_configure() {
+	eqmake5 PREFIX="${EPREFIX}/usr" ${PN}.pro
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+}