1 files changed, 50 insertions, 0 deletions
diff --git a/app-admin/supervisor/supervisor-3.3.3.ebuild b/app-admin/supervisor/supervisor-3.3.3.ebuild
new file mode 100644
index 000000000000..7dba0e2b7cd7
--- /dev/null
+++ b/app-admin/supervisor/supervisor-3.3.3.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )	# py2 only
+# xml.etree.ElementTree module required.
+PYTHON_REQ_USE="xml"
+
+inherit distutils-r1
+
+MY_PV="${PV/_beta/b}"
+
+DESCRIPTION="A system for controlling process state under UNIX"
+HOMEPAGE="http://supervisord.org/ https://pypi.org/project/supervisor/"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${PN}-${MY_PV}.tar.gz"
+
+LICENSE="repoze ZPL BSD HPND GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/meld3[${PYTHON_USEDEP}]
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		${RDEPEND}
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	newinitd "${FILESDIR}/init.d-r1" supervisord
+	newconfd "${FILESDIR}/conf.d" supervisord
+	use doc && local HTML_DOCS=( docs/.build/html/. )
+	distutils-r1_python_install_all
+}