gentoo resync : 10.02.2019

4 files changed, 174 insertions, 161 deletions

diff --git a/www-client/w3mmee/Manifest b/www-client/w3mmee/Manifest
index 743b1db71de0..c5d98d0a7b72 100644
--- a/www-client/w3mmee/Manifest
+++ b/www-client/w3mmee/Manifest
@@ -7,6 +7,7 @@ AUX w3mmee-time.patch 608 BLAKE2B 1c380c5af1cfba502e5749810456944aa2eb52a3e73ee1
 AUX w3mmee-tinfo.patch 357 BLAKE2B 33ef18109515e789debcfe3a0addc67be0a69853bfda0e732ecde65c4271990dd93582c9f6a1e124679bafd75176c1da318a0c4f8d8e6310a792aea66777fa04 SHA512 ec9bb5936d55d2c2edab7c1ae025f72ddf7734a2b8c2dc152c1cb9eeba42db42c2072232924aed92f40cfd7218eafd9d57bd4bf5b5f8380569b0703a6bc1eb25
 AUX w3mmee-w3mman.patch 631 BLAKE2B b155487da7120b5e106c7b747a7cfc0d3157bdd651da8d324dc262b66ac47c88380e4ab4ed546522199ab3c3b89177b3ec83c5dffba56708ca57de0ba19d7281 SHA512 a883127315a7a5d9354c17a05c1dc4127ab7a72bb46b02592953b83bde54ca4c12f756b1ef44127f9d74517ed1ec1640ef2e187f809b15c906769f1e9e699527
 DIST w3mmee-p24-22.tar.gz 690094 BLAKE2B 9b779122a10f606fab8cfe9e3ffde7473f60ee65591de3a1eca241e563ced7c70260670da7c56c9eaf39010180733933eba039d743e723b0cc8c230ef8a31d81 SHA512 85d4d373a5a544f8c4fbc37e8344daaa5eae3ae007a0280c693aa8946c8cbf63f3fc92fb69c2597286921254e3234f29ee1b3f21e1c9d498b39a597a51e98761
-EBUILD w3mmee-0.3.2_p24-r10.ebuild 3787 BLAKE2B 0d3a28053adddb7217831b396d2112489f64cc81af228f33325903b465dd685df9b7af3922fdcf100392a01bd93a27a6bf3b3334be88667cbaa7fd321540486f SHA512 f7081989f96fd586fbcfcd22a8dee3886d5dd35dcabeccc701a6c67d41ad711abfaf3e4c202306a4d6be3948387c3616f9b8e5df05000a5d7774ab35918bdfba
-EBUILD w3mmee-0.3.2_p24-r7.ebuild 3798 BLAKE2B f56bc27f87bffe62f1751065cdfa1df2460c53a0580df30705ac3075b10aba6da27b1270adfe682a0354db275cbddf7874230bb708b8bfa30d50b3a1d0d6334b SHA512 5e443c58e85ed51ef0c793b0cbd70ec6f2376f8b4414693ba3eda49bdb45baa9570242f8d24b947f62f4559ad90e4966cb6b43f95ca52fa70264188293d7f624
+DIST w3mmee-p24-23.tar.gz 697342 BLAKE2B cdfd5752a29ee486ccb4cb174ac68aa2b93c818a088e28a8938ef308030b4baac69645e5adcf86361297f79b2473de483917f523bdd0cda0f6d0d93cc0755534 SHA512 fa74b9124e0790461ea7936411f89265c8a367326bf1bba7a5ea5f4abf748197e0926847f9860ec8d35e97f0e53bcdc69821fdd9d741fc8b18b5e11211aa3271
+EBUILD w3mmee-0.3.2_p24-r10.ebuild 3831 BLAKE2B 7fc6f1094f012938a8d69f95bedcb03636247fca6b22526dc530e272b21e6845c75e3f4eed9e72ff6353d8a982bc70d5ab41daeb70b9e128a9e59a86a0f4b884 SHA512 7a622fa47ccab3f458424da26374ec12493494b12ed61e2e9fde3f128e97e693f3b5a2446b15fdae9f7f7ff62a6e3e15b6ae71744ecc619a5f416c68123c01b5
+EBUILD w3mmee-0.3.2_p24-r11.ebuild 3834 BLAKE2B cd439d7e32a103a4ee7dd119cc909f8d00e219641b71f7464050f389e07f19739113c5d16bf7d6d6137234eb107496d22d3e237941ea4eed86ca1fc7fbeed49b SHA512 ca639a7d84a2764f6dd3a33b5ce5b753a68f0f8da068b6640b368c7cd3a4911c8f6b0832077dc050bcadeece30cc2a606b7ae5e1b2622a2966dc3200cc820e31
 MISC metadata.xml 234 BLAKE2B 8615ff091e2c6b2c5d9d4246dbec2ed0c5161ce154a59f492bc640a1428de7847757b68a8d926cae4bf78905d2aeeda10cb4cb0db9bf6870d38e811556299520 SHA512 16ea852f76297335e7ef70c8019fe09d46c0455922c049ba6e92696232e957955fd671d467ebdd0bf7837d39a26083d5be2a6f8abeba53807f0b8c5b97f2e441
diff --git a/www-client/w3mmee/w3mmee-0.3.2_p24-r10.ebuild b/www-client/w3mmee/w3mmee-0.3.2_p24-r10.ebuild
index d6d4ada34ca0..6572d1840d46 100644
--- a/www-client/w3mmee/w3mmee-0.3.2_p24-r10.ebuild
+++ b/www-client/w3mmee/w3mmee-0.3.2_p24-r10.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI="6"
@@ -13,7 +13,7 @@ HOMEPAGE="http://pub.ks-and-ks.ne.jp/prog/w3mmee/"
 SRC_URI="http://pub.ks-and-ks.ne.jp/prog/pub/${MY_P}.tar.gz"
 
 SLOT="0"
-LICENSE="public-domain"
+LICENSE="w3m"
 KEYWORDS="amd64 ppc x86"
 IUSE="gpm imlib libressl nls ssl xface"
 
@@ -51,6 +51,7 @@ HTML_DOCS=( 00INCOMPATIBLE.html )
 src_prepare() {
 	default
 
+	sed -i "s:/lib\([^a-z$]\):/$(get_libdir)\1:g" configure
 	sed -i "/^AR=/s:ar:$(tc-getAR):" XMakefile
 }
 
diff --git a/www-client/w3mmee/w3mmee-0.3.2_p24-r11.ebuild b/www-client/w3mmee/w3mmee-0.3.2_p24-r11.ebuild
new file mode 100644
index 000000000000..40f99bb5bbd4
--- /dev/null
+++ b/www-client/w3mmee/w3mmee-0.3.2_p24-r11.ebuild
@@ -0,0 +1,168 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit alternatives multilib toolchain-funcs
+
+MY_PV="${PV##*_}-23"
+MY_P="${PN}-${MY_PV}"
+
+DESCRIPTION="A variant of w3m with support for multiple character encodings"
+HOMEPAGE="http://pub.ks-and-ks.ne.jp/prog/w3mmee/"
+SRC_URI="http://pub.ks-and-ks.ne.jp/prog/pub/${MY_P}.tar.gz"
+
+SLOT="0"
+LICENSE="w3m"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="gpm imlib libressl nls ssl xface"
+
+DEPEND=">=dev-libs/boehm-gc-7.2
+	dev-libs/libmoe
+	dev-lang/perl
+	sys-libs/ncurses:0=
+	sys-libs/zlib
+	imlib? (
+		media-libs/imlib
+		xface? ( media-libs/compface )
+	)
+	gpm? ( sys-libs/gpm )
+	nls? ( sys-devel/gettext )
+	ssl? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:0= )
+	)"
+RDEPEND="${DEPEND}"
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-boehm-gc.patch
+	"${FILESDIR}"/${PN}-gcc-4.4.patch
+	"${FILESDIR}"/${PN}-gcc-4.5.patch
+	"${FILESDIR}"/${PN}-glibc-2.14.patch
+	"${FILESDIR}"/${PN}-rc_name.patch
+	"${FILESDIR}"/${PN}-time.patch
+	"${FILESDIR}"/${PN}-tinfo.patch
+	"${FILESDIR}"/${PN}-w3mman.patch
+)
+DOCS=( ChangeLog NEWS{,.mee} README )
+HTML_DOCS=( 00INCOMPATIBLE.html )
+
+src_prepare() {
+	default
+
+	sed -i "s:/lib\([^a-z$]\):/$(get_libdir)\1:g" configure
+	sed -i "/^AR=/s:ar:$(tc-getAR):" XMakefile
+}
+
+src_configure() {
+	local myconf=(
+		-locale_dir=$(usex nls "${EPREFIX}/usr/share/locale" '(NONE)')
+	)
+	local myuse=(
+		display_code=E
+		system_code=E
+		use_ansi_color=y
+		use_cookie=y
+		use_history=y
+		use_mouse=$(usex gpm y n)
+	)
+
+	if use ssl; then
+		myconf+=(
+			--ssl-includedir="${EPREFIX}/usr/include/openssl"
+			--ssl-libdir="${EPREFIX}/usr/$(get_libdir)"
+		)
+		myuse+=(
+			use_digest_auth=y
+			use_ssl=y
+			use_ssl_verify=y
+		)
+	else
+		myuse+=( use_ssl=n )
+	fi
+	if use imlib; then
+		myuse+=(
+			use_image=y
+			use_w3mimg_fb=n
+			use_w3mimg_x11=y
+			use_xface=$(usex xface y n)
+			w3mimgdisplay_setuid=n
+		)
+	else
+		myuse+=( use_image=n )
+	fi
+
+	cat <<-EOF >> config.param
+	lang=MANY
+	accept_lang=en
+	EOF
+
+	env CC=$(tc-getCC) "${myuse[@]}" ./configure \
+		-nonstop \
+		-prefix="${EPREFIX}/usr" \
+		-suffix=mee \
+		-auxbindir="${EPREFIX}/usr/$(get_libdir)/${PN}" \
+		-libdir="${EPREFIX}/usr/$(get_libdir)/${PN}/cgi-bin" \
+		-helpdir="${EPREFIX}/usr/share/${PN}" \
+		-mandir="${EPREFIX}/usr/share/man" \
+		-sysconfdir="${EPREFIX}/etc/${PN}" \
+		-model=custom \
+		-libmoe="${EPREFIX}/usr/$(get_libdir)" \
+		-mb_h="${EPREFIX}/usr/include/moe" \
+		-mk_btri="${EPREFIX}/usr/libexec/moe" \
+		-cflags="${CFLAGS}" \
+		-ldflags="${LDFLAGS}" \
+		"${myconf[@]}" \
+		|| die
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	einstalldocs
+
+	# w3mman and manpages conflict with those from w3m
+	mv "${ED}"/usr/share/man/man1/w3m{,mee}.1 || die
+	mv "${ED}"/usr/share/man/ja/man1/w3m{,mee}.1 || die
+
+	docinto html/en
+	dodoc doc/*.html
+	rm -f doc/*.html
+	docinto en
+	dodoc doc/{HISTORY,README,keymap,menu}*
+
+	docinto html/ja
+	dodoc doc-jp/*.html
+	rm -f doc-jp/*.html
+	docinto ja
+	dodoc doc-jp/{HISTORY,README,keymap,menu}*
+}
+
+pkg_postinst() {
+	w3m_alternatives
+	einfo
+	einfo "If you want to render multilingual text, please refer to"
+	einfo "/usr/share/doc/${PF}/en/README.mee or"
+	einfo "/usr/share/doc/${PF}/jp/README.mee"
+	einfo "and set W3MLANG variable respectively."
+	einfo
+}
+
+pkg_postrm() {
+	w3m_alternatives
+}
+
+w3m_alternatives() {
+	if [[ ! -f /usr/bin/w3m ]]; then
+		alternatives_makesym /usr/bin/w3m \
+			/usr/bin/w3m{m17n,mee}
+		alternatives_makesym /usr/bin/w3mman \
+			/usr/bin/w3m{man-m17n,meeman}
+		alternatives_makesym /usr/share/man/ja/man1/w3m.1.gz \
+			/usr/share/man/ja/man1/w3m{m17n,mee}.1.gz
+		alternatives_makesym /usr/share/man/man1/w3m.1.gz \
+			/usr/share/man/man1/w3m{m17n,mee}.1.gz
+		alternatives_makesym /usr/share/man/man1/w3mman.1.gz \
+			/usr/share/man/man1/w3m{man-m17n,meeman}.1.gz
+	fi
+}
diff --git a/www-client/w3mmee/w3mmee-0.3.2_p24-r7.ebuild b/www-client/w3mmee/w3mmee-0.3.2_p24-r7.ebuild
deleted file mode 100644
index 1e8125a3e72a..000000000000
--- a/www-client/w3mmee/w3mmee-0.3.2_p24-r7.ebuild
+++ /dev/null
@@ -1,157 +0,0 @@
-# Copyright 1999-2018 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=0
-
-inherit alternatives eutils multilib toolchain-funcs
-
-MY_PV="${PV##*_}-22"
-MY_P="${PN}-${MY_PV}"
-
-DESCRIPTION="A variant of w3m with support for multiple character encodings"
-HOMEPAGE="http://pub.ks-and-ks.ne.jp/prog/w3mmee/"
-SRC_URI="http://pub.ks-and-ks.ne.jp/prog/pub/${MY_P}.tar.gz"
-
-SLOT="0"
-LICENSE="public-domain"
-KEYWORDS="amd64 ppc x86"
-IUSE="gpm imlib nls ssl xface"
-
-DEPEND=">=dev-libs/boehm-gc-7.2
-	>=dev-libs/libmoe-1.5.3
-	dev-lang/perl
-	>=sys-libs/ncurses-5.2-r3
-	>=sys-libs/zlib-1.1.3-r2
-	imlib? (
-		>=media-libs/imlib-1.9.8
-		xface? ( media-libs/compface )
-	)
-	gpm? ( >=sys-libs/gpm-1.19.3-r5 )
-	nls? ( sys-devel/gettext )
-	ssl? ( >=dev-libs/openssl-0.9.6b )"
-RDEPEND="${DEPEND}"
-S="${WORKDIR}/${MY_P}"
-
-src_unpack() {
-	unpack ${A}
-	cd "${S}"
-	epatch "${FILESDIR}"/${PN}-boehm-gc.patch
-	epatch "${FILESDIR}"/${PN}-gcc-4.4.patch
-	epatch "${FILESDIR}"/${PN}-gcc-4.5.patch
-	epatch "${FILESDIR}"/${PN}-glibc-2.14.patch
-	epatch "${FILESDIR}"/${PN}-rc_name.patch
-	epatch "${FILESDIR}"/${PN}-time.patch
-	epatch "${FILESDIR}"/${PN}-tinfo.patch
-	epatch "${FILESDIR}"/${PN}-w3mman.patch
-	sed -i "/^AR=/s:ar:$(tc-getAR):" XMakefile || die
-}
-
-src_compile() {
-	local myconf myuse
-	myuse="use_cookie=y use_ansi_color=y use_history=y
-		display_code=E system_code=E"
-
-	if use ssl; then
-		myconf="${myconf} --ssl-includedir=/usr/include/openssl
-			--ssl-libdir=/usr/$(get_libdir)"
-		myuse="${myuse} use_ssl=y use_ssl_verify=y use_digest_auth=y"
-	else
-		myuse="${myuse} use_ssl=n"
-	fi
-
-	if use gpm; then
-		myuse="${myuse} use_mouse=y"
-	else
-		myuse="${myuse} use_mouse=n"
-	fi
-
-	if use nls; then
-		myconf="${myconf} -locale_dir=/usr/share/locale"
-	else
-		myconf="${myconf} -locale_dir='(NONE)'"
-	fi
-
-	if use imlib; then
-		myuse="${myuse} use_image=y use_w3mimg_x11=y
-		use_w3mimg_fb=n w3mimgdisplay_setuid=n"
-		if use xface; then
-			myuse="${myuse} use_xface=y"
-		else
-			myuse="${myuse} use_xface=n"
-		fi
-	else
-		myuse="${myuse} use_image=n"
-	fi
-
-	cat <<-EOF >> config.param
-	lang=MANY
-	accept_lang=en
-	EOF
-
-	env CC=$(tc-getCC) ${myuse} ./configure \
-		-nonstop \
-		-prefix=/usr \
-		-suffix=mee \
-		-auxbindir=/usr/$(get_libdir)/${PN} \
-		-libdir=/usr/$(get_libdir)/${PN}/cgi-bin \
-		-helpdir=/usr/share/${PN} \
-		-mandir=/usr/share/man \
-		-sysconfdir=/etc/${PN} \
-		-model=custom \
-		-libmoe=/usr/$(get_libdir) \
-		-mb_h=/usr/include/moe \
-		-mk_btri=/usr/libexec/moe \
-		-cflags="${CFLAGS}" \
-		-ldflags="${LDFLAGS}" \
-		${myconf} \
-		|| die
-
-	emake || die "emake failed"
-}
-
-src_install() {
-	emake DESTDIR="${D}" install || die
-	dodoc ChangeLog NEWS* README
-	dohtml 00INCOMPATIBLE.html
-
-	# w3mman and manpages conflict with those from w3m
-	mv "${D}"/usr/share/man/man1/w3m{,mee}.1 || die
-	mv "${D}"/usr/share/man/ja/man1/w3m{,mee}.1 || die
-
-	docinto en
-	dodoc doc/{HISTORY,README,keymap,menu}*
-	dohtml doc/*
-
-	docinto jp
-	dodoc doc-jp/{HISTORY,README,keymap,menu}*
-	dohtml doc-jp/*
-}
-
-pkg_postinst() {
-	w3m_alternatives
-	einfo
-	einfo "If you want to render multilingual text, please refer to"
-	einfo "/usr/share/doc/${PF}/en/README.mee or"
-	einfo "/usr/share/doc/${PF}/jp/README.mee"
-	einfo "and set W3MLANG variable respectively."
-	einfo
-}
-
-pkg_postrm() {
-	w3m_alternatives
-}
-
-w3m_alternatives() {
-	if [[ ! -f /usr/bin/w3m ]]; then
-		alternatives_makesym /usr/bin/w3m \
-			/usr/bin/w3m{m17n,mee}
-		alternatives_makesym /usr/bin/w3mman \
-			/usr/bin/w3m{man-m17n,meeman}
-		alternatives_makesym /usr/share/man/ja/man1/w3m.1.gz \
-			/usr/share/man/ja/man1/w3m{m17n,mee}.1.gz
-		alternatives_makesym /usr/share/man/man1/w3m.1.gz \
-			/usr/share/man/man1/w3m{m17n,mee}.1.gz
-		alternatives_makesym /usr/share/man/man1/w3mman.1.gz \
-			/usr/share/man/man1/w3m{man-m17n,meeman}.1.gz
-	fi
-}