gentoo resync : 10.02.2020

1 files changed, 66 insertions, 0 deletions

diff --git a/www-client/dillo/dillo-3.1_p20181005.ebuild b/www-client/dillo/dillo-3.1_p20181005.ebuild
new file mode 100644
index 000000000000..80b643685578
--- /dev/null
+++ b/www-client/dillo/dillo-3.1_p20181005.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools desktop toolchain-funcs
+
+DESCRIPTION="Lean FLTK based web browser"
+HOMEPAGE="https://www.dillo.org/"
+SRC_URI="
+	https://dev.gentoo.org/~jer/${P}.tar.xz
+	mirror://gentoo/${PN}.png
+"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~mips ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc +gif ipv6 +jpeg +png ssl +xembed"
+
+RDEPEND="
+	>=x11-libs/fltk-1.3
+	sys-libs/zlib
+	jpeg? ( virtual/jpeg:0 )
+	png? ( >=media-libs/libpng-1.2:0 )
+	ssl? ( net-libs/mbedtls:= )
+"
+DEPEND="
+	${RDEPEND}
+	doc? ( app-doc/doxygen )
+"
+PATCHES=(
+	"${FILESDIR}"/${PN}2-inbuf.patch
+	"${FILESDIR}"/${PN}-3.0.5-fno-common.patch
+)
+DOCS="AUTHORS ChangeLog README NEWS doc/*.txt doc/README"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf  \
+		$(use_enable gif) \
+		$(use_enable ipv6) \
+		$(use_enable jpeg) \
+		$(use_enable png) \
+		$(use_enable ssl) \
+		$(use_enable xembed) \
+		--docdir="/usr/share/doc/${PF}"
+}
+
+src_compile() {
+	emake AR=$(tc-getAR)
+	if use doc; then
+		doxygen Doxyfile || die
+	fi
+}
+
+src_install() {
+	default
+
+	use doc && dodoc -r html
+
+	doicon "${DISTDIR}"/${PN}.png
+	make_desktop_entry ${PN} Dillo
+}