gentoo auto-resync : 20:09:2022 - 11:23:36

1 files changed, 56 insertions, 0 deletions

diff --git a/sys-power/acpid/acpid-2.0.34.ebuild b/sys-power/acpid/acpid-2.0.34.ebuild
new file mode 100644
index 000000000000..ec53324174f6
--- /dev/null
+++ b/sys-power/acpid/acpid-2.0.34.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit linux-info systemd
+
+DESCRIPTION="Daemon for Advanced Configuration and Power Interface"
+HOMEPAGE="https://sourceforge.net/projects/acpid2/"
+SRC_URI="mirror://sourceforge/${PN}2/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~loong ~riscv ~x86"
+IUSE="selinux"
+
+RDEPEND="selinux? ( sec-policy/selinux-apm )"
+DEPEND=">=sys-kernel/linux-headers-3"
+
+pkg_pretend() {
+	local CONFIG_CHECK="~INPUT_EVDEV"
+	local WARNING_INPUT_EVDEV="CONFIG_INPUT_EVDEV is required for ACPI button event support."
+	[[ ${MERGE_TYPE} != buildonly ]] && check_extra_config
+}
+
+pkg_setup() { :; }
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	newdoc kacpimon/README README.kacpimon
+	dodoc -r samples
+	rm -f "${D}"/usr/share/doc/${PF}/COPYING || die
+
+	exeinto /etc/acpi
+	newexe "${FILESDIR}"/${PN}-1.0.6-default.sh default.sh
+	exeinto /etc/acpi/actions
+	newexe samples/powerbtn/powerbtn.sh powerbtn.sh
+	insinto /etc/acpi/events
+	newins "${FILESDIR}"/${PN}-1.0.4-default default
+
+	newinitd "${FILESDIR}"/${PN}-2.0.26-init.d ${PN}
+	newconfd "${FILESDIR}"/${PN}-2.0.16-conf.d ${PN}
+
+	systemd_dounit "${FILESDIR}"/${PN}.{service,socket}
+}
+
+pkg_postinst() {
+	if [[ -z ${REPLACING_VERSIONS} ]]; then
+		elog
+		elog "You may wish to read the Gentoo Linux Power Management Guide,"
+		elog "which can be found online at:"
+		elog "https://wiki.gentoo.org/wiki/Power_management/Guide"
+		elog
+	fi
+}