gentoo resync : 29.12.2022

1 files changed, 53 insertions, 0 deletions

diff --git a/sys-fs/mac-fdisk/mac-fdisk-0.1_p18-r1.ebuild b/sys-fs/mac-fdisk/mac-fdisk-0.1_p18-r1.ebuild
new file mode 100644
index 000000000000..dad62e50d2ac
--- /dev/null
+++ b/sys-fs/mac-fdisk/mac-fdisk-0.1_p18-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit toolchain-funcs flag-o-matic
+
+DESCRIPTION="Mac/PowerMac disk partitioning utility"
+HOMEPAGE="ftp://ftp.mklinux.apple.com/pub/Other_Tools/"
+SRC_URI="
+	mirror://debian/pool/main/m/mac-fdisk/${PN}_${PV/_p*}.orig.tar.gz
+	mirror://debian/pool/main/m/mac-fdisk/${PN}_${PV/_p*}-${PV/*_p}.diff.gz
+"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 -riscv ~x86"
+
+S=${WORKDIR}/${P/_p*}.orig
+PATCHES=(
+	"${WORKDIR}"/${PN}_${PV/_p*}-${PV/*_p}.diff
+	"${FILESDIR}"/largerthan2gb.patch
+	"${FILESDIR}"/${PN}-0.1-headers.patch
+	# Patch for bug #142737
+	"${FILESDIR}"/${PN}-0.1_p16-ppc64.patch
+	### Patch for building on amd64
+	"${FILESDIR}"/${PN}-amd64.patch
+	# Patch for large (>550GB disks)
+	# Note that >=2TB disks may not work due to limitations of the Mac
+	# Partition Table structure, this needs to be investigated
+	"${FILESDIR}"/big_pt.patch
+	"${FILESDIR}"/${PN}-0.1_p16-ppc-inline.patch
+	"${FILESDIR}"/${PN}-0.1_p18-lseek64.patch
+	# add support for partitioning 2TB drives
+	"${FILESDIR}"/${PN}-0.1_p18-2tb.patch
+	"${FILESDIR}"/${PN}-0.1_p18-musl.patch
+)
+
+src_compile() {
+	use elibc_musl && append-cppflags -Dloff_t=off_t
+	emake CC="$(tc-getCC)"
+}
+
+src_install() {
+	into /
+	newsbin pdisk mac-fdisk
+	newsbin fdisk pmac-fdisk
+
+	into /usr
+	newman mac-fdisk.8.in mac-fdisk.8
+	newman pmac-fdisk.8.in pmac-fdisk.8
+
+	dodoc debian/changelog README HISTORY
+}